Assistance System 1.10b

library AssistanceSystem initializer Init_AssistanceSystem, needs GetPlayerNameColored

//=====Assistance System 1.20=====\\

globals
    // Configuration Options:
    private constant real Time = 10. // Time after latest damage after which no more assistance given
    private constant integer Award = 125 // Bonus gold for getting an assist
    private constant boolean Split = true // Whether to split award gold between all players who get an assist
    private constant string Msg1 = "With assistance from " // Starting portion of assistance message
    private constant string Msg2 = " gold!" // Message after the amount of gold is displayed
    private constant string Msg3 = " gold a piece!" // Same as above, except for multiple assisters
    private constant string GoldColor = "" // Color code for the color you would like the bounty value displayed in
    
//=====Don't touch past this point=====\\
    private unit array Targets
    private timer array Timers
    private timer array T
    private trigger Trigger1 = CreateTrigger() 
    private trigger Trigger2 = CreateTrigger()
    private group Heroes = CreateGroup()
    private integer Skip
    private integer Total
    
    public integer array Assists // Can be accessed publically as AssistanceSystem_Assists[playerid]
endglobals
//*************************************************************************

private function Reset takes nothing returns nothing
    local integer i = 0
    local timer t = GetExpiredTimer()
    
    loop
        exitwhen Timers[i]==t
        
        if i>Total then
            call BJDebugMsg("AS Error: |cffff0000No reset timer found.")
            set t = null
            return
        endif
        set i = i + 1
    endloop
    
    call PauseTimer(t)
    set t = null
    set Timers[i] = null
    set Targets[i] = null
endfunction
private function Timer takes nothing returns nothing
    local unit dam = GetEventDamageSource()
    local player pdam = GetOwningPlayer(dam)
    local unit targ = GetTriggerUnit()
    local player ptarg = GetOwningPlayer(targ)
    local integer i = GetPlayerId(ptarg)+(Skip*GetPlayerId(pdam))
    
    if not IsUnitEnemy(dam,ptarg) or pdam==ptarg or GetEventDamage()<.1 then
        set targ = null
        set dam = null
        return
    endif
    
    if Timers[i]==null then
        if T[i]==null then
            set T[i] = CreateTimer()
        endif
        set Timers[i] = T[i]
        set Targets[i] = targ
        call TimerStart(Timers[i],Time,false,function Reset)
    else
        call PauseTimer(Timers[i])
        call TimerStart(Timers[i],Time,false,function Reset)
    endif
    
    set dam = null
    set targ = null
endfunction

private function Death takes nothing returns nothing
    local unit killer = GetKillingUnit()
    local player pkill = GetOwningPlayer(killer)
    local unit dieer = GetTriggerUnit()
    local integer i = GetPlayerId(GetOwningPlayer(dieer))
    local integer id = i
    local player array pa
    local integer count = 0
    local integer playid
    local string msg 
    local string endmsg = Msg2
    local integer gold = Award
    
    loop
        exitwhen i>Total
        if Targets[i]==dieer then
            if pkill!=Player((i-id)/Skip) then
                set count = count + 1
                set playid = (i-id)/Skip
                set pa[count] = Player(playid)
                set Assists[playid] = Assists[playid] + 1
            endif
            set Targets[i] = null
            call PauseTimer(Timers[i])
            set Timers[i] = null
        endif
        
        set i = i + Skip
    endloop
    
    if count==0 then
        set killer = null
        set dieer = null
        return
    elseif count>1 then
        set endmsg = Msg3
    endif
    if Split then
        set gold = Award/count
    endif
    
    set i = 1
    set msg = Msg1 + GetPlayerNameColored(pa[i])
    loop
        exitwhen i>count
        call SetPlayerState(pa[i], ConvertPlayerState(1), GetPlayerState(pa[i], ConvertPlayerState(1)) + gold)
        set i = i + 1
    endloop
    set i = 2
    set count = count - 1
    loop
        exitwhen i>count
        set msg = msg + ", " + GetPlayerNameColored(pa[i])
        set i = i + 1
    endloop
    if count>0 then
        set msg = msg + " and " + GetPlayerNameColored(pa[i])
    endif
    set msg = msg + ".  +"+GoldColor+I2S(gold)+"|r"+endmsg 
    call DisplayTextToForce(bj_FORCE_ALL_PLAYERS,msg)
    
    set killer = null
    set dieer = null
endfunction

// Start the system for the unit
public function Register takes unit u returns nothing
    if IsUnitInGroup(u,Heroes) then
        call BJDebugMsg("AS Error: |cffff0000"+GetUnitName(u)+" has already been registered with the system.")
        return
    endif
    call GroupAddUnit(Heroes,u)
    call TriggerRegisterUnitEvent(Trigger1, u, EVENT_UNIT_DAMAGED)
    call TriggerRegisterUnitEvent(Trigger2, u, EVENT_UNIT_DEATH)
endfunction

private function Init_AssistanceSystem takes nothing returns nothing
    local integer i = GetPlayers()-1
    
    call TriggerAddAction( Trigger1, function Timer)
    call TriggerAddAction( Trigger2, function Death)
    
    set Skip = i+1
    set Total = (Skip*i)+i-1
endfunction

endlibrary