Conversation System - Likes / Dislikes

//Empties out the current conversation
function ClearConvo takes nothing returns nothing

//This sets up the current convo, adding a choice displayed as 'name', that, when the player presses the appropriate key, 
//has the current hero say 'say', the sound 'play' is played, and, once the sound either finishes or ESC is pressed, the
//callback 'caller' is called (where callback is a function interface or boolexpr or similar). Returns false if all five slots are full
function ConvoAddChoice takes string name, string say, callback caller, sound play returns boolean

//Displays all choices avaliable
function DisplayConvo takes nothing returns nothing

library Characters initializer Init

    function interface Callback takes nothing returns nothing

    globals
        private constant real DELAY = .1
        private boolean autoskip = false
        
        private boolean ESCAPE = false
        private timer T=CreateTimer()
        private boolean active
        private Callback Call
    endglobals

    private function CallEscape takes nothing returns nothing
        set active=false
        call Call.execute()
    endfunction
    
    private function SetEscape takes nothing returns nothing
        set active=false
        call PauseTimer(T)
        call TimerStart(T,DELAY,false,function CallEscape)
    endfunction
    
    struct Hero
        private static timer camT = CreateTimer()
        private static unit camTarget
        unit main
        playercolor color
        string name
        
        static method create takes string name, unit u, playercolor c returns Hero
            local Hero h=Hero.allocate()
            set h.main=u
            set h.color=c
            set h.name=name
            call SetUnitColor(u,c)
            return h
        endmethod
        
        private static method camLock takes nothing returns nothing
            call ResetToGameCamera(.04)
            call SetCameraTargetController(.camTarget,0,0,false)
        endmethod
        
        method lockCameraTo takes nothing returns nothing
            set .camTarget = .main
            call TimerStart(.camT,.02,true,function Hero.camLock)
        endmethod
        
        static method unlockCamera takes nothing returns nothing
            call PauseTimer(.camT)
        endmethod
        
        method say takes string text, Callback c, real dur returns nothing
            if(not autoskip)then
                set dur=9999999.
            endif
            call SetCinematicScene(GetUnitTypeId(.main),.color,.name,text,dur,0)
            set Call = c
            set active=true
            call TimerStart(T,dur,false,function CallEscape)
        endmethod
        
        method order takes string order returns boolean
            return IssueImmediateOrder(.main,order)
        endmethod
        
        method orderPoint takes string order, real x, real y returns boolean
            return IssuePointOrder(.main,order,x,y)
        endmethod
        
        method orderTarget takes string order, widget target returns boolean
            return IssueTargetOrder(.main,order,target)
        endmethod
        
        method operator show= takes boolean which returns nothing
            call ShowUnit(.main,which)
        endmethod
        
        method operator paused= takes boolean which returns nothing
            call PauseUnit(.main,which)
        endmethod
        
        method operator x= takes real xa returns nothing
            call SetUnitX(.main,xa)
        endmethod
        
        method operator y= takes real ya returns nothing
            call SetUnitY(.main,ya)
        endmethod
        
        method operator facing= takes real f returns nothing
            call SetUnitFacing(.main,f)
        endmethod
        
        method operator x takes nothing returns real
            return GetUnitX(.main)
        endmethod
        
        method operator y takes nothing returns real
            return GetUnitY(.main)
        endmethod
        
        method operator facing takes nothing returns real
            return GetUnitFacing(.main)
        endmethod
    endstruct
    
    private function Cond takes nothing returns boolean
        return active
    endfunction
    
    private function Init takes nothing returns nothing
        local trigger t=CreateTrigger()
        call TriggerRegisterPlayerEvent(t,Player(0),EVENT_PLAYER_END_CINEMATIC)
        call TriggerAddCondition(t,Condition(function Cond))
        call TriggerAddAction(t,function SetEscape)
    endfunction
    
    //! textmacro NewHero takes NAME, ID, OWNER, COLOR
        library $NAME$ initializer init
            globals
                Hero $NAME$
            endglobals
            private function init takes nothing returns nothing
                set $NAME$=Hero.create("$NAME$",CreateUnit(Player($OWNER$),'$ID$',0,0,0),ConvertPlayerColor($COLOR$))
                set $NAME$.show=false
            endfunction
        endlibrary
    //! endtextmacro
endlibrary
//! runtextmacro NewHero( "Feyman", "h000", "0", "4" )
//! runtextmacro NewHero( "Daren", "h001", "0", "0" )
//! runtextmacro NewHero( "Jerod", "h002", "1", "1" )
//! runtextmacro NewHero( "Luna", "h003", "2", "15" )