38 variables in spell pack

//scopes are very good, inside this scope everything will be 
//called FatalStrike_funcName, the "initialozer Init " tells the 
//scope that the function that initializes this trigger is Init
scope FatalStrike initializer Init 
    
    //this is global free declaration
    //"private" means it can only be used by this spell
    //"constant" means its value never changes
    //private constants like this integer are excelent to make spells easy to configuure
    globals 
        //rawcode of the ability
        private constant integer AID = 'A00B'  
        
        //string model of teh effect. This way is easier to change !
        private constant string EFFSTRING = "Abilities\\Spells\\Undead\\DeathPact\\DeathPactTarget.mdl"
        
        //the amount of damage the caster will take
        private constant integer DAMAGE = 200
        
        //the rawcode of the dummy purple unit
        private constant integer DUMMYID = 'h001'
        
        //the rawcode of FatalStrike the dummy will receive
        private constant integer FATALSTRIKE = 'A009'
    endglobals
    
//===========================================================================
    private function Actions takes nothing returns nothing
        //locals are used inside functions, they make your spells MUI
        //I save the catser in this variable
        local unit caster = GetTriggerUnit()
        
        //this stores the X and Y of the caster.
        //with an X and an Y, you have the location of the caster
        //and because you use 2 reals, this won't leak
        local real casterX = GetUnitX(caster)
        local real casterY = GetUnitY(caster)
        
        //this is a varuable for the dummy unit
        //it has no value yet
        local unit dum
        
        //instead of pausing the caster, making him invulnerable and adding him 
        //fly height for him to disappear, we just hide the caster
        call ShowUnit(caster, false)
        
        //we play the caster's death animation
        call SetUnitAnimation( caster, "death" )
        
        //We create and destroy an effect at the casters position
        call DestroyEffect(AddSpecialEffect(EFFSTRING, casterX, casterY))
        
        //here we wait one second. Waits are evil and inacurate, i suggest you use
        //timers as soon as you can
        call TriggerSleepAction(1.0)
        
        //here we make caster appear
        call ShowUnit(caster, true)

        //here we remove 200 life from caster
        //SetWidgetLife and GetWidgetLife set and get the life of the unit
        call SetWidgetLife(caster, GetWidgetLife(caster) - DAMAGE)
        
        //we play attack animation
        call SetUnitAnimation( caster, "attack" )
        
        //here we set a value for teh dummy unit
        //we say that variable dum is a the unit we are creating at caster's position
        set dum = CreateUnit(GetOwningPlayer(caster), DUMMYID, casterX, casterY, 0)
        
        //here we add 3 seconds of life to dummy
        //the 'BTLF' is just "buff" it has. Not important in dummies
        //you can always use that one.
        call UnitApplyTimedLife(dum, 'BTLF', 3.0)
        
        //here we add fatal strike to the dummy uniy
        call UnitAddAbility(dum, FATALSTRIKE)
        
        //here we order the dummy unit to cast fan of knifes immediatly
        call IssueImmediateOrder(dum, "fanofknives")
        
        //now that the spell has ended, we have to clean all mess to prevent leaks
        //we take care of the variables of type "unit"
        //varuables of type real and integer, per example, don't leak
        set caster = null
        set dum = null
    endfunction
//===========================================================================
  //functions can also be provate, meaning they can only be used by this spell
    private function Conditions takes nothing returns boolean
        return GetSpellAbilityId() == AID
    endfunction
//===========================================================================    
    private function Init takes nothing returns nothing
        local trigger FatalStrike = CreateTrigger(  )
        
        call TriggerRegisterAnyUnitEventBJ( FatalStrike, EVENT_PLAYER_UNIT_SPELL_EFFECT )
        call TriggerAddCondition( FatalStrike, Condition( function Conditions ) )
        call TriggerAddAction( FatalStrike, function Actions )
        
        set FatalStrike = null
    endfunction
endscope