Item Fusion

library libItems initializer InitItems

globals
  private integer array combo_id
  private integer array comp_1
  private integer array comp_2
  private integer array comp_3
  private integer array comp_4
  private integer array comp_5
  private integer array comp_6
  private integer num_recipes = 0
endglobals

function AddRecipe takes integer combo, integer c1, integer c2, integer c3, integer c4, integer c5, integer c6 returns nothing
  set combo_id[num_recipes] = combo
  set comp_1[num_recipes] = c1
  set comp_2[num_recipes] = c2
  set comp_3[num_recipes] = c3
  set comp_4[num_recipes] = c4
  set comp_5[num_recipes] = c5
  set comp_6[num_recipes] = c6
  set num_recipes = num_recipes + 1
endfunction
function OnGetItem takes nothing returns nothing
  local unit u = GetManipulatingUnit ()
  local item it = GetManipulatedItem ()
  local integer iid = GetItemTypeId (it)
  local integer i = 0
  local integer j
  local integer k
  local integer array req
  local boolean array rem
  loop
    exitwhen i >= num_recipes
    set req[0] = comp_1[i]
    set req[1] = comp_2[i]
    set req[2] = comp_3[i]
    set req[3] = comp_4[i]
    set req[4] = comp_5[i]
    set req[5] = comp_6[i]
    set j = 0
    loop
      exitwhen j > 5
      set it = UnitItemInSlot (u, j)
      set rem[j] = false
      if it != null then
        set iid = GetItemTypeId (it)
        set k = 0
        loop
          exitwhen k > 5
          if iid == req[k] then
            set req[k] = 0
            set rem[j] = true
            set k = 6
          endif
          set k = k + 1
        endloop
      endif
      set j = j + 1
    endloop
    if (req[0] == 0) and (req[1] == 0) and (req[2] == 0) and (req[3] == 0) and (req[4] == 0) and (req[5] == 0) then
      set j = 0
      loop
        exitwhen j > 5
        if rem[j] then
          set it = UnitRemoveItemFromSlot (u, j)
          call RemoveItem (it)
        endif
        set j = j + 1
      endloop
      call UnitAddItemById (u, combo_id[i])
      call DestroyEffect (AddSpecialEffectTarget ("Abilities\\Spells\\Items\\AIem\\AIemTarget.mdl", u, "origin"))
      set i = num_recipes
    endif
    set i = i + 1
  endloop
  set u = null
  set it = null
endfunction

private function InitItems takes nothing returns nothing
  local trigger trg = CreateTrigger ()
  call TriggerRegisterAnyUnitEventBJ (trg, EVENT_PLAYER_UNIT_PICKUP_ITEM)
  call TriggerAddAction (trg, function OnGetItem)
  set trg = null

  // Add your recipes here. First ID is the result, then up to 6 components.
  call AddRecipe ('I009', 'I00B', 'I007', 'I008', 0, 0, 0)
  // etc etc etc
endfunction

endlibrary