HELP! Some newbie JASS questions

// Minimalistic CSData/HSAS
// Paste it into your custom script section

// GetHandleIndex will return a unique number for each handle.
// Use it in combination with global arrays.

function H2I takes handle h returns integer
    return h
    return 0
endfunction

function GetHandleIndex takes handle h returns integer
    local integer index=H2I(h)-0x100000

// For debugging. Remove if you are very confident in that your map does not leak.
    if index>8190 then
        call BJDebugMsg("|cffff3333Attachment Warning! Index is greater than 8190.|r")
    endif

    return index
endfunction

// Create a unit array
// udg_xUnits[]

function KillUnitTimed_Expires takes nothing returns nothing
    local timer t=GetExpiredTimer()
    local integer index = GetHandleIndex(t)

// Kill Unit
    call UnitApplyTimedLife(udg_xUnits[index],'BTLF',0)
    set udg_xUnits[index]=null

    call ReleaseTimer(t)
    set t=null
endfunction

function KillUnitTimed takes unit u, integer time returns nothing
    local timer t=NewTimer()

// We now store the unit in the array.
// GetHandleIndex will return a unique number for our timer.
    set udg_xUnits[GetHandleIndex(t)] = u

    call TimerStart(t,time,false,function KillUnitTimed_Expires)

// Well. Better to be on the safe side, aight? :)
    set t=null
endfunction

//***************************************************
//*                                                 *
//* XT Attachment System                            *
//* By: Themerion                                   *
//*
//*
//* Needs these variables:
//* - integer XTn
//* - integer XToffset
//* - timer   XTstack  array(200)
//*                                                 *
//***************************************************

function XT_H2I takes handle h returns integer
    return h
    return 0
endfunction
//------------------------------------------------------------------------------

function XT_New takes nothing returns timer
   set udg_XTn=udg_XTn+1
   return udg_XTstack[udg_XTn]
endfunction

function XT_Release takes timer t returns nothing
    set udg_XTstack[udg_XTn]=t
    set udg_XTn=udg_XTn-1
endfunction

function XT_Index takes timer t returns integer
    return XT_H2I(t)-udg_XToffset
endfunction
//===========================================================================
function InitTrig_XT takes nothing returns nothing

    set udg_XToffset=XT_H2I(udg_XTstack[0])

// Initial configuration check.
    if udg_XTstack[100]==null then
        call BJDebugMsg("|cffff3333Warning:|r\n|cffffcc00Increase the array size of the variable 'XTstack'.|r\n(200 recommended)")
    endif
endfunction

//===========================================================================
//====== </XT> ==============================================================
//===========================================================================

XT_New()    // Acquires a new timer with an index! Must be released instead of destroyed.
XT_Release(t)    // Release timers acquired with XT_New()
XT_Index(t)    // You can only get indexes for timers acquired with XT_New()