Help with limiting a unit in a spell

library LimitedSummon initializer Init needs TimerUtils
    
    //===============================
    // These values are configurable.
    //===============================
    globals
        private constant integer SPELL_ID =     'A001'  // Enter the rawcode of your spell here.
        private constant integer SUMMON_ID =    'hgtw'  // Enter the rawcode of your summoned unit here.
        private constant integer SUMMON_LIMIT = 3       // Enter the maximum number of summon units
        private constant real TIMED_LIFE =      0       // If you want timed life, set to a positive value.

        private constant string SUMMON_FX =     "Abilities\\Spells\\Items\\TomeOfRetraining\\TomeOfRetrainingCaster.mdl"
    //===================================
    // The rest shouldn't need tampering.
    //===================================
        private constant integer BUFF_ID =      'BFig'  // Summoned unit buff for timed life.
        
        private integer summon_count =          0
        private group summon_group =            null
        private unit array summoned
    endglobals

//===========================================================================
    private function GetOccupiedIndex takes nothing returns integer
        local integer i = 0
        loop
            exitwhen summoned[i] != null or i == SUMMON_LIMIT
            set i = i+1
        endloop
        return i
    endfunction
    
    private function GetEmptyIndex takes nothing returns integer
        local integer i = 0
        loop
            exitwhen summoned[i] == null or i == SUMMON_LIMIT
            set i = i+1
        endloop
        return i
    endfunction
    
    private function actions takes nothing returns nothing
        local unit u = null
        local effect fx = null
        
        if summon_count >= SUMMON_LIMIT then
            call KillUnit(summoned[GetOccupiedIndex()])
        endif
        
        set u = CreateUnitAtLoc(GetTriggerPlayer(),SUMMON_ID,GetSpellTargetLoc(),GetUnitFacing(GetTriggerUnit()))
        set summoned[GetEmptyIndex()] = u
        set summon_count = summon_count+1
        call GroupAddUnit(summon_group,u)
        if TIMED_LIFE > 0 then
            call UnitAddType(u,UNIT_TYPE_SUMMONED)
            call UnitApplyTimedLife(u,BUFF_ID,TIMED_LIFE)
        endif
        
        set fx = AddSpecialEffect(SUMMON_FX,GetUnitX(u),GetUnitY(u))
        call DestroyEffect(fx)

        set u = null
        set fx = null
    endfunction

    private function conditions takes nothing returns boolean
        return GetSpellAbilityId() == SPELL_ID
    endfunction
//===========================================================================

    private function ResortArray takes integer startIndex returns nothing
        local integer i = startIndex
        loop
            set summoned[i] = summoned[i+1]
            set i = i+1
            exitwhen i == SUMMON_LIMIT
        endloop
    endfunction

    private function Clean_actions takes nothing returns nothing
        local unit u = GetTriggerUnit()
        local integer i = 0
        set summon_count = summon_count-1
        call GroupRemoveUnit(summon_group,u)
        loop
            exitwhen summoned[i] == u
            set i = i+1
        endloop
        set summoned[i] = null
        call ResortArray(i)
        set u = null
    endfunction
    
    private function Clean_conditions takes nothing returns boolean
        return IsUnitInGroup(GetTriggerUnit(),summon_group)
    endfunction
//===========================================================================
    globals
        public trigger trig = null
        public trigger clean = null
    endglobals

    private function Init takes nothing returns nothing
        set summon_group = CreateGroup()
        set trig = CreateTrigger()
        set clean = CreateTrigger()
        
        call TriggerRegisterAnyUnitEventBJ( trig, EVENT_PLAYER_UNIT_SPELL_EFFECT )
        call TriggerAddCondition( trig, Condition( function conditions ) )
        call TriggerAddAction( trig, function actions )

        call TriggerRegisterAnyUnitEventBJ( clean, EVENT_PLAYER_UNIT_DEATH )
        call TriggerAddCondition( clean, Condition( function Clean_conditions ) )
        call TriggerAddAction( clean, function Clean_actions )
    endfunction

endlibrary