Long-term Dynamic Arrays

library DynamicArrays initializer init
// note:  DataArray is used to store used/free space while MainArray is used for the dynamic array data.
// note2: a negative number in the Data array means the magnitude is being used while a positive number
// means the magnitude is free.
globals
    private constant integer MAX_SIZE = 32760
    private integer array MainArray[MAX_SIZE]
    private integer array DataArray[MAX_SIZE]
endglobals

struct DynamicArray
    private integer start
    private integer size
    
    static method create takes integer size returns DynamicArray
        local DynamicArray a = DynamicArray.allocate()
        local integer temp = 0
        local integer tempsize
        if size <= 0 then
            call a.destroy()
            return 0
        endif
        loop
            if temp >= MAX_SIZE then
                call a.destroy()
                return 0
            endif
            if DataArray[temp] > size then // enough free
                set a.start = temp
                set a.size = size
                set tempsize = DataArray[temp]
                set DataArray[temp] = -size
                set temp = temp + size
                if DataArray[temp] == 0 then
                    set DataArray[temp] = tempsize - size
                endif
                exitwhen true
            else
                if DataArray[temp] < 0 then // slots taken till
                    set temp = temp - DataArray[temp]
                else // not enough room in this allocation
                    set temp = temp + DataArray[temp]
                endif
            endif
        endloop
        return a
    endmethod
    
    method operator [] takes integer i returns integer
        if not (i < .size) then
            return 0
        else
            return MainArray[.start+i]
        endif
    endmethod
    
    method operator []= takes integer i, integer data returns nothing
        if not (i < .size) then
            return
        else
            set MainArray[.start+i] = data
        endif
    endmethod
    
    method onDestroy takes nothing returns nothing
        local integer temp  = 0
        local integer tempback = 0
        local integer tempforward = 0
        loop
            exitwhen temp == .start
            set tempback = temp
            if DataArray[temp] > 0 then
                set temp = temp + DataArray[temp]
            else
                set temp = temp - DataArray[temp]
            endif
        endloop
        set DataArray[temp] = .size
        set tempforward = temp + .size
        if DataArray[tempforward] > 0 then // sub it's index and add to front
            set DataArray[temp] = DataArray[temp] + DataArray[tempforward]
            set DataArray[tempforward] = 0
        endif
        if tempback != temp and DataArray[tempback] > 0 then // add to it's index
            set DataArray[tempback] = DataArray[tempback] + DataArray[temp]
            set DataArray[temp] = 0
        endif
        set .start = 0
        set .size = 0
    endmethod      
endstruct

function CheckDynamicArraysData takes nothing returns nothing
    local integer i = 0
    local string out = ""
    loop
        exitwhen i >= MAX_SIZE
        if DataArray[i] > 0 then
            set out = out + "[|cff00ff00"+I2S(i)+" - "+I2S(i+DataArray[i]-1)+"|r]"
            set i = i + DataArray[i]
        else
            set out = out + "[|cffff0000"+I2S(i)+" - "+I2S(i-DataArray[i]-1)+"|r]"
            set i = i - DataArray[i]
        endif
    endloop
    call BJDebugMsg(out)
endfunction

private function init takes nothing returns nothing
    set DataArray[0] = MAX_SIZE
endfunction

endlibrary