Overgrowth

//***************************
//* version 1.05
//***************************

scope Overgrowth initializer init

    //*** Spell Configuration ***
    globals
        private constant integer ID = 'A000'
        // the rawcode of the ability in your map
        private constant integer ENTANGLE = 'A001'
        // the rawcode of the entangle ability in your map
        private constant integer BUFF = 'B000'
        // the rawcode of the entangle buff in your map
        private constant string ORDERSTRING = "entanglingroots"
        // the orderstring of the entangle ability, no changes are necessary
        private constant string ROOTMODEL = "Abilities\\Spells\\NightElf\\EntanglingRoots\\EntanglingRootsTarget.mdl"
        // the modelpath of the "roots" effect you want
        private constant real MINROOTSCALE = 0.75
        private constant real MAXROOTSCALE = 2.5
        // scaling of the "roots" effect model
        private constant real ROOTDIST = 100.
        // distance in between roots special effects
        private constant real INTERVAL = 0.06
        // interval of how fast vines "expand"
    endglobals
    private constant function Duration takes integer lvl returns real
        return 4. //The duration of the buff, be sure this is the same duration as the buff-applier ability
    endfunction
    private constant function MaxTargets takes integer lvl returns integer
        return 0 //How many targets are hit. A value of 1 means it doesn't bounce. Use 0 to have unlimited number of bounces
    endfunction
    private constant function SeekDistance takes integer lvl returns real
        return 600. //The range at which a target is seeked out to bounce on to
    endfunction
    private constant function CollisionSize takes integer lvl returns real
        return 50. // The range at which a target is hit
    endfunction
    private function EffectConfiguration takes xefx fx returns nothing
        set fx.fxpath = ROOTMODEL
        set fx.scale = GetRandomReal(MINROOTSCALE,MAXROOTSCALE)
        set fx.xyangle = GetRandomReal(0,360)
        // Use this to configure how the effects look. If you don't know how to
        // configure this, check the xefx readme, I've included it here
        // just in case.
    endfunction
    private function TargetsAllowed takes unit getfilterunit, player owningplayer returns boolean
        return IsUnitEnemy(getfilterunit,owningplayer) and not IsUnitType(getfilterunit,UNIT_TYPE_MECHANICAL) and GetWidgetLife(getfilterunit) > .405 and not IsUnitType(getfilterunit,UNIT_TYPE_FLYING) and GetUnitAbilityLevel(getfilterunit,BUFF) == 0
        // use this to configure the types of units qualified as targets to bounce on.
    endfunction
    
    //*** Spell Code ***

    private struct data
        unit u = null
        unit t = null
        integer lvl = 0
        integer count = 0
        real x = 0
        real y = 0
        xecast cast = 0
    endstruct
    
    
    globals
        private GroupGet_Distance GG_Distance = 0
        private unit tempUnit = null
        private group temp = CreateGroup()
        private player passPlayer = null
        private real tempD = 0
    endglobals
    
    private function enum takes nothing returns boolean
        return TargetsAllowed(GetFilterUnit(),passPlayer) and IsUnitInRangeXY(GetFilterUnit(),GG_Distance.x,GG_Distance.y,tempD)
    endfunction
    
    private function conditions takes nothing returns boolean
        return GetSpellAbilityId() == ID
    endfunction
    
    private function destroyfx takes nothing returns nothing
        call xefx.destroy(xefx( GetTimerData(GetExpiredTimer()) ))
        call ReleaseTimer(GetExpiredTimer())
    endfunction

    private function startfx takes xefx fx, real dur returns nothing
    local timer t = NewTimer()
        call SetTimerData(t,fx)
        call TimerStart(t, dur, false, function destroyfx)
        set t = null
    endfunction
    
    private function loopfunc takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local data d = data(GetTimerData(t))
    local xefx fx = 0
    local real a = 0
    local real tx = 0
    local real ty = 0
        if d.t == null or GetWidgetLife(d.t) < .405 then
        // there is no target or the target has died, look for another
            set passPlayer = GetOwningPlayer(d.u)
            set tempUnit = d.u
            set tempD = SeekDistance(d.lvl) + XE_MAX_COLLISION_SIZE
            set GG_Distance.x = d.x
            set GG_Distance.y = d.y
            call GroupEnumUnitsInRange(temp,d.x,d.y,tempD,Condition(function enum))
            call GroupRemoveUnit(temp,d.t)
            set d.t = GroupGetLowestEx(temp,GG_Distance)
            set d.count = d.count + 1
            set passPlayer = null
            set tempUnit = null
        endif
        if (MaxTargets(d.lvl) > 0 and d.count > MaxTargets(d.lvl)) or d.t == null then
            //Max number of targets reached, end the spell
            call d.cast.destroy()
            call d.destroy()
            call ReleaseTimer(t)
        else
        //Found a target!
            set tx = GetUnitX(d.t)
            set ty = GetUnitY(d.t)
            set a = Atan2(ty-d.y,tx-d.x)
            set d.x = d.x + ROOTDIST * Cos(a)
            set d.y = d.y + ROOTDIST * Sin(a)
            set fx = xefx.create(d.x,d.y,0)
            call EffectConfiguration(fx)
            call startfx(fx,Duration(d.lvl))
            if (tx-d.x)*(tx-d.x)+(ty-d.y)*(ty-d.y) <= CollisionSize(d.lvl)*CollisionSize(d.lvl) then
                //target's distance is less than CollisionSize, entangle it
                call d.cast.castOnTarget(d.t)
                set d.t = null
            endif

        endif
        set t = null
    endfunction
    
    private function actions takes nothing returns nothing
    local timer t = NewTimer()
    local data d = data.create()
        set d.u = GetTriggerUnit()
        set d.t = GetSpellTargetUnit()
        set d.lvl = GetUnitAbilityLevel(d.u,ID)
        set d.x = GetUnitX(d.u)
        set d.y = GetUnitY(d.u)
        set d.count = 1
        set d.cast = xecast.createBasic(ENTANGLE,OrderId(ORDERSTRING),GetOwningPlayer(d.u))
        set d.cast.recycledelay = Duration(d.lvl)
        call SetTimerData(t,d)
        call TimerStart(t,INTERVAL,true,function loopfunc)
        set t = null
    endfunction
    
    //*** Spell Initialization ***
    private function init takes nothing returns nothing
     local trigger t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_SPELL_EFFECT)
        call TriggerAddCondition(t,Condition(function conditions))
        call TriggerAddAction(t,function actions)
        set GG_Distance = GroupGet_Distance.create()
        set t = null
    endfunction

endscope