With the latest release of the
Jass NewGen Pack, the latest installment of Reinventing the Craft(RtC) has been released to the public.
RtC is a big pack of natives created by SFilip and me, in an attempt to create an enhanced experience when making and playing maps. RtC includes natives such as vectors for integer arrays with no limit, events for detecting keyboard presses and mouse position/presses that wasn't previously possible, natives that returns the time of the computer being used, binary comparisons, StringPos and StringReplace that doesn't leak strings, 64bit sized integers, and wrappers for Winsock which gives you full networking control. Also being worked on is natives to give you dynamic tooltips and object names, among other things. RtC is still in active development, and we're always listening to ideas.
Here's a few examples:
MouseAPI
JASS:
scope MouseTest initializer Init
globals
private trigger t
endglobals
private function Actions takes nothing returns nothing
call BJDebugMsg("(" + R2S(GetMouseTargetX()) + ", " + R2S(GetMouseTargetY()) + ")")
endfunction
private function Init takes nothing returns nothing
set t = CreateTrigger()
call TriggerAddAction(t, function Actions)
call TriggerRegisterMouseEvent(t, EVENT_LMOUSEDOWN)
endfunction
endscope
KeyboardAPI
JASS:
scope KeyboardTest initializer Init
globals
private trigger t
endglobals
private function Actions takes nothing returns nothing
local integer key = GetTriggerParam_Integer(0)
call BJDebugMsg("Key = " + I2S(key))
endfunction
private function Init takes nothing returns nothing
set t = CreateTrigger()
call TriggerAddAction(t, function Actions)
call TriggerRegisterKeyEvent(t, 1)
endfunction
endscope
Vector
JASS:
library RtCVector
struct vector extends array
static method create takes integer size returns vector
return CreateVector(size)
endmethod
method copy takes nothing returns vector
local vector iv = vector.create(this.size)
local integer i = 0
loop
exitwhen i >= this.size
set iv[i] = this[i]
set i = i + 1
endloop
return iv
endmethod
method free takes nothing returns nothing
call DestroyVector(this)
endmethod
method clear takes nothing returns nothing
call VectorClear(this)
endmethod
method operator size takes nothing returns integer
return GetVectorSize(this)
endmethod
method operator size= takes integer newsize returns nothing
call SetVectorSize(this, newsize)
endmethod
method operator [] takes integer index returns integer
if(index >= this.size) then
debug call BJDebugMsg("|cffff0000" + SCOPE_PREFIX + "Error: Reading out of bounds!|r")
return 0
endif
return VectorGet(this, index)
endmethod
method operator []= takes integer index, integer value returns nothing
if(index >= this.size) then
set this.size = index + 1
endif
call VectorSet(this, index, value)
endmethod
method push takes integer value returns nothing
call VectorPushBack(this, value)
endmethod
method pop takes nothing returns nothing
call VectorPopBack(this)
endmethod
method peek takes nothing returns integer
return VectorBack(this)
endmethod
method empty takes nothing returns boolean
return VectorEmpty(this)
endmethod
endstruct
endlibrary JASS:
library Test initializer Init requires RtCVector
private function Init takes nothing returns nothing
local vector iv = vector.create(0)
local integer i = 0
call BJDebugMsg("iv.size = " + I2S(iv.size))
call iv.push(20)
call iv.push(5)
call iv.push(60)
call iv.push(202)
call BJDebugMsg("iv.size = " + I2S(iv.size))
set i = 0
loop
exitwhen i >= iv.size
call BJDebugMsg("iv[" + I2S(i) + "] = " + I2S(iv[i]))
set i = i + 1
endloop
call iv.clear()
call iv.push(5)
set i = 0
loop
exitwhen i >= iv.size
call BJDebugMsg("iv[" + I2S(i) + "] = " + I2S(iv[i]))
set i = i + 1
endloop
call iv.push(20)
call iv.push(5)
call iv.push(60)
call iv.push(202)
set iv.size = 10
loop
exitwhen iv.empty()
call BJDebugMsg("iv.peek = " + I2S(iv.peek()))
call iv.pop()
endloop
call iv.free()
endfunction
endlibrary
We're hoping that coming in future installments will be even more natives, that gives mappers the control they really need. As already said, we're open to suggestions. And the more people that test and use it the better. The best way to see what's available is to look at the RtC folder inside newgen, there's a file called RtCCommon.j, which in the bottom has all of our currently implemented new stuff. The two last sections are experimental and not yet fully functional, so use at your own risk.
Also, here's the beginning of a manual.
MouseAPI
Enjoy.
