Shield System

//*****************************************************************
//*  Shield System - created by rain.mon
//*
//*         HOW TO USE
//*
//*     Just call CreateShield(whichUnit,shieldHP,BarColor,BuffID)
//*     whichUnit is the unit that you want to create a shield on.
//*     shieldHP is the damage the shield blocks in total.
//*     BarColor is the color of the custom floating bar which shows the shields hp.
//*     The color is the default color code that Warcraft 3 uses.
//*     BuffID can be either set to 0 or to a buff id. If it set to 0 that will
//*     make the shield last until destroyed and undispellable. If it is set to a
//*     real buff id it will get removed when the buff expires from the unit either
//*     from a dispell or from its duration.
//*
//*         CREDITS
//*
//*     shadow1500 - For getting the bar formula from his system.
//*****************************************************************
library ShieldSystem initializer Init

    globals
        private constant integer BarLenght = 32 // The number of BarChars for every shield bar.
        private constant string BarChar = "'" // The character which indicates the bars hp.
        private constant real BarSize = 12.5 // The font size of the Shield Bar
        private constant real BarOffsetX = -60. // The X offset from the shielded unit.
        private constant real BarOffsetY = 5. // The Y offset from the shielded unit.
    endglobals

    globals
        private group Registered = CreateGroup()
        private trigger Trig = CreateTrigger()
    endglobals
    
    struct shield
        unit u
        real hp
        real maxhp
        texttag tt
        string bar
        string color
        integer buffid
        
        static integer total = 0
        static shield array sa
        static constant timer stimer = CreateTimer()
        
        method onDestroy takes nothing returns nothing
            call DestroyTextTag(.tt)
        endmethod
        
        static method Damage takes nothing returns nothing
            local integer i = 0
            local shield s
            local unit damaged = GetTriggerUnit()
            local real damage = GetEventDamage()
            
            loop
                exitwhen i >= .total
                set s = shield.sa[i]
                if s.u == damaged then
                    if damage > s.hp then
                        call SetWidgetLife(s.u,GetWidgetLife(s.u)+s.hp)
                        call s.destroy()
                        set s.total = s.total - 1
                        set s.sa[i] = s.sa[s.total]
                        set i = i - 1
                    else
                        set s.hp = s.hp - damage
                        call SetWidgetLife(s.u,GetWidgetLife(s.u)+damage)
                    endif
                endif
                set i = i + 1
            endloop
            
            if s.total == 0 then
                call PauseTimer(shield.stimer)
            endif
        endmethod
        
        static method Update takes nothing returns nothing
            local integer i = 0
            local integer Y
            local boolean bool
            local real x
            local real y
            local shield s
            
            loop
                exitwhen i >= .total
                set s = shield.sa[i]
                set Y = 0
                set bool = false
                set s.bar = "["+s.color
                loop
                    exitwhen Y==BarLenght
                    if (not bool) and (s.hp < (Y * (s.maxhp/BarLenght))+1) then
                        set bool = true
                        set s.bar = s.bar+"|r|cFF000000"
                    else
                        set s.bar = s.bar+BarChar
                    endif
                    set Y = Y + 1
                endloop
                set s.bar = s.bar+"|r]"
                set x = GetUnitX(s.u)+BarOffsetX
                set y = GetUnitY(s.u)+BarOffsetY
                call SetTextTagText(s.tt,s.bar,BarSize * 0.023 / 10)
                call SetTextTagPos(s.tt,x,y,140)
                call SetTextTagVisibility(s.tt,IsUnitVisible(s.u,GetLocalPlayer()))
                if s.buffid != 0 and GetUnitAbilityLevel(s.u, s.buffid) <= 0 then
                    call s.destroy()
                    set s.total = s.total - 1
                    set s.sa[i] = s.sa[s.total]
                    set i = i - 1
                endif
                set i = i + 1
            endloop
        endmethod
    
        static method create takes unit u, real HP, string color, integer buffid returns shield
            local shield s = shield.allocate()
            local shield st
            local integer i = 0
            
            loop
                exitwhen i >= s.total
                set st = s.sa[i]
                if u == st.u then
                    call st.destroy()
                    set s.total = s.total - 1
                    set s.sa[i] = s.sa[s.total]
                    set i = i - 1
                endif
                set i = i + 1
            endloop
            
            set s.u = u
            set s.hp = HP
            set s.maxhp = HP
            set s.color = color
            set s.tt = CreateTextTag()
            set s.buffid = buffid
            call SetTextTagPermanent(s.tt,true)
            call SetTextTagVisibility(s.tt,IsUnitVisible(s.u,GetLocalPlayer()))
            
            if not IsUnitInGroup(s.u,Registered) then
                call TriggerRegisterUnitEvent(Trig,s.u,EVENT_UNIT_DAMAGED)
                call GroupAddUnit(Registered,s.u)
            endif
            
            if s.total == 0 then
                call TimerStart(s.stimer,0.01,true,function shield.Update)
            endif
            
            set s.sa[.total] = s
            set s.total = s.total + 1
            return s
        endmethod
    endstruct
    
    function CreateShield takes unit u, real hp, string color, integer buffid returns nothing
        call shield.create(u,hp,color,buffid)
    endfunction
    
    function Init takes nothing returns nothing
        call TriggerAddAction(Trig,function shield.Damage)
    endfunction
endlibrary