Crtical Strike + ADamage = code opinion!

//===========================================================================
//A JESP spell that causes the attacker to deal extra damage to an enemy unit
//on an attack. Nearby allied units are then healed by the damaged caused.
//
//@author Flame_Phoenix 
//
//Requires:
// - Adamage
// - xebasic and xedamage
//
//@credits:
// - Anitarf, for ADamage
// - Vexorian, for xebasic and xedamage
// - Moyack, for helping on improving this script
// - 0zyx0, for telling me how to make this script more efficient
//
//@version 1.3.2
//===========================================================================
scope WolfStrike initializer Init
//===========================================================================
//=============================SETUP START===================================
//===========================================================================
    globals
        private constant integer AID = 'A023'   //rw of the hero ability
        private constant string ALLY_EFFECT = "Abilities\\Spells\\Undead\\DeathPact\\DeathPactTarget.mdl"  //heal effect that will appear on healed units
        private constant string ENEMY_EFFECT = "Objects\\Spawnmodels\\Other\\BeastmasterBlood\\BeastmasterBlood.mdl"    //Damage effect that will appear on damage units
        private constant string FIRE_EFF = "Abilities\\Weapons\\RedDragonBreath\\RedDragonMissile.mdl"  //an extra effect on the victim to make it look cooler =P
    endglobals
    
    private function Radius takes integer level returns real
    //the radius of the heal
        return level * 200.
    endfunction
    
    private function HealTargets takes unit attacker, unit friend returns boolean
    //the targets(friends) that will be healed with the damage caused
        return IsUnitAlly(friend, GetOwningPlayer(attacker)) and (IsUnitType(friend, UNIT_TYPE_STRUCTURE) == false) and (IsUnitType(friend, UNIT_TYPE_MECHANICAL) == false) and (GetWidgetLife(friend) > 0.405) 
    endfunction
    
    private function Chances takes integer level returns real
    //the chances the caster has of causing extra damage
        return 1.//level * 0.1
    endfunction
    
    private function Damage takes real dam, integer level returns real
    //the extra damage caused
        return dam * (level + 0.5)
    endfunction
    
    private function setupDamageOptions takes xedamage d returns nothing
       set d.dtype = DAMAGE_TYPE_NORMAL   
       set d.atype = ATTACK_TYPE_NORMAL 
    endfunction

//===========================================================================
//=============================SETUP END=====================================
//===========================================================================
    globals
        private group g
        private boolexpr b
        private unit tmpAtt
        private xedamage damageOptions
        private timer damageTime    //timer that will be started at 0.0 to deal the extra damage
    endglobals
    
    private struct aVictim 
        unit attacker
        unit victim
        real extraDam
        integer level
        
        static method create takes unit att, unit vic, real bonusDam returns aVictim
            local aVictim this = aVictim.allocate()
            
            set .attacker = att
            set .victim = vic
            set .extraDam = bonusDam
            set .level = GetUnitAbilityLevel(att, AID)
            
            return this
        endmethod
    endstruct
//===========================================================================
    private function Targets takes nothing returns boolean
        return HealTargets(tmpAtt, GetFilterUnit())
    endfunction
//===========================================================================
    private function Conditions takes unit attacker, unit victim returns boolean 
        return (GetRandomReal(0, 1) <= Chances(GetUnitAbilityLevel(attacker, AID))) and (GetUnitAbilityLevel(attacker, AID) > 0) and (damageOptions.isInUse()==false) and IsUnitEnemy(victim, GetOwningPlayer(attacker)) and (IsUnitType(victim, UNIT_TYPE_STRUCTURE)==false) and (IsUnitType(victim, UNIT_TYPE_MECHANICAL)==false)
    endfunction
//===========================================================================
    private function DoDamage takes nothing returns nothing
        local aVictim thisVic = aVictim(GetTimerData(GetExpiredTimer()))
        
        //deal damage and release the timer !
        call damageOptions.damageTarget(thisVic.attacker, thisVic.victim, thisVic.extraDam)
        call ReleaseTimer(GetExpiredTimer())
    endfunction
//===========================================================================
    private function Actions takes unit damagedUnit, unit damageSource, real damage, real prevented returns nothing
        local integer lv  //level of the ability
        local real bonus    //bonus damage
        local texttag text //the nice textag
        local unit f
        local aVictim thisVic   //this will keep information about the damage we will cause
        
        if Conditions(damageSource, damagedUnit) then  
            set lv = GetUnitAbilityLevel(damageSource, AID) 
            set text = CreateTextTag()  
            set bonus = damage + Damage(damage, lv)
            set damageTime = NewTimer()
            set thisVic = aVictim.create(damageSource, damagedUnit, bonus)
            
            //Let's make the unit look as if it is taking fire, how? Let's make a fireball effect explode on them:
            call DestroyEffect( AddSpecialEffectTarget(FIRE_EFF, damagedUnit, "origin") ) 

            // We know it is a valid target, let's damage it?
            // we are retrieving the level from the struct's members, and it is used in
            // a simple damage formula, for every level the damage increases by 25.
            call SetTimerData(damageTime, integer(thisVic))
            call TimerStart(damageTime, 0.0, false, function DoDamage)
            
            call DestroyEffect(AddSpecialEffect(ENEMY_EFFECT, GetUnitX(damagedUnit), GetUnitY(damagedUnit)))
            
            set tmpAtt = damageSource
            call GroupEnumUnitsInRange(g, GetUnitX(damageSource), GetUnitY(damageSource), Radius(lv), b)
            loop
                set f = FirstOfGroup(g)
                exitwhen(f == null)
                call GroupRemoveUnit(g, f)
                    
                call SetWidgetLife(f, GetWidgetLife(f) + bonus)
                call DestroyEffect(AddSpecialEffect(ALLY_EFFECT, GetUnitX(f), GetUnitY(f)))
            endloop
                
            call SetTextTagText(text, I2S(R2I(bonus)) + "!", 0.024)
            call SetTextTagPos(text, GetUnitX(damageSource), GetUnitY(damageSource), 0.00)
            call SetTextTagColor(text, 255, 0, 0, 255)
            call SetTextTagVelocity(text, 0, 0.04)
            call SetTextTagVisibility(text, true)
            call SetTextTagFadepoint(text, 2)
            call SetTextTagLifespan(text, 5)
            call SetTextTagPermanent(text, false)
        endif
        
        set text = null
    endfunction
//===========================================================================
    private function Init takes nothing returns nothing
        call ADamage_AddResponse( ADamage_Response.Actions )
        
        // Initializing the damage options:
        set damageOptions=xedamage.create()    // first instanciate a xeobject.
        call setupDamageOptions(damageOptions) // now call the function we saw before.
        
        //setting globals
        set g = CreateGroup()
        set b = Condition(function Targets)
        
        //Preloading effects
        call Preload(ALLY_EFFECT)
        call Preload(ENEMY_EFFECT)
        call Preload(FIRE_EFF)
    endfunction
endscope

local trigger WolfStrikeTrg = CreateTrigger(  )

private constant damagetype DTYPE = DAMAGE_TYPE_NORMAL
private constant weapontype ATYPE = WEAPON_TYPE_NORMAL
//...
set damageOptions.dtype = DTYPE
set damageOptions.atype = ATYPE

private constant damagetype DTYPE = DAMAGE_TYPE_NORMAL
private constant weapontype ATYPE = WEAPON_TYPE_NORMAL
//...
set damageOptions.dtype = DTYPE
set damageOptions.atype = ATYPE