| So for my Race Contest #2 submission, I need a way to produce a cursor on the screen for a player, to which end I devised a library. The library produces a cursor for a specific player and a specific unit, then executes functions onClick and onCancel.
That part works fine... sort of. The issue I'm having is the cancel detection trigger is firing when it shouldn't be.
What it boils down to is this: - There is a periodic timer that, each time it times out, forces the player to press the cancel detection ability
- The system detects a click
- The onClick function removes the cancel detection ability, pauses the unit, orders it to stop, and unpauses the unit, and then the timer used in the periodic function is paused and released.
- Somehow, immediately after onClick is called, onCancel is also called... but only some of the time
What's perplexing about this is that: - It only happens occasionally.
- The only way onCancel can be called is if the unit is successfully ordered to use the cancel ability... but after onClick the unit does NOT have the ability any more. Additionally, the timer that runs the periodic function should have stopped running, so even if the unit still had the ability it wouldn't be ordered to use it anyway.
So, I have no idea what's going on... but maybe someone else has an idea. Here's the code:
 JASS: library ShowCursor initializer Init requires TimerUtils
globals
private constant integer CANCEL_DETECTION_ABILITY = 'Cncl'
private constant string CANCEL_DETECTION_HOTKEY = "l"
private constant string CANCEL_DETECTION_ORDERSTRING = "starfall"
private constant real CANCEL_PERIOD = 0.50
private constant string CAST_ORDERSTRING = "flare"
private constant string CAST_HOTKEY = "i"
constant integer CURSOR_TYPE_GROUND = 0
constant integer CURSOR_TYPE_UNIT = 1
constant integer CURSOR_TYPE_UNIT_OR_GROUND = 2
constant integer CURSOR_TYPE_AOE_100 = 3
public integer array CursorTypeAbilities
endglobals
//! textmacro RegisterCastType takes NAME, ABILITY_ID
set CursorTypeAbilities[$NAME$] = '$ABILITY_ID$'
//! endtextmacro
private function CursorInit takes nothing returns nothing
//! runtextmacro RegisterCastType("CURSOR_TYPE_GROUND", "TGnd")
//! runtextmacro RegisterCastType("CURSOR_TYPE_UNIT", "TUnt")
//! runtextmacro RegisterCastType("CURSOR_TYPE_UNIT_OR_GROUND", "TUoG")
//! runtextmacro RegisterCastType("CURSOR_TYPE_AOE_100", "T100")
endfunction
function interface CursorClick takes player sourcePlayer, unit sourceUnit, real targX, real targY, widget targWidget returns boolean
function interface CursorCancel takes player sourcePlayer, unit sourceUnit returns nothing
globals
private trigger CancelTrig = null
private trigger ClickTrig = null
private keyword CursorData
private CursorData array CDArray
endglobals
private struct CursorData
unit Source = null
player P
CursorClick ClickFunc
CursorCancel CancelFunc
integer CursorType
timer T = null
boolean Ignore = false
static method operator [] takes player P returns CursorData
return CDArray[GetPlayerId(P)]
endmethod
endstruct
private function OnCancelOrder takes nothing returns boolean
local unit U = GetTriggerUnit()
local CursorData C
if GetIssuedOrderId() == OrderId(CANCEL_DETECTION_ORDERSTRING) and GetUnitAbilityLevel(U, CANCEL_DETECTION_ABILITY) > 0 then
call BJDebugMsg("...cancel...")
set C = CursorData[GetOwningPlayer(U)]
call PauseTimer(C.T)
call ReleaseTimer(C.T)
set C.T = null
call PauseUnit(U, true)
call IssueImmediateOrder(U, "stop")
call PauseUnit(U, false)
call UnitRemoveAbility(U, CANCEL_DETECTION_ABILITY)
call UnitRemoveAbility(U, CursorTypeAbilities[C.CursorType])
call C.CancelFunc.execute(C.P, C.Source)
endif
set U = null
return false
endfunction
private function OnClickOrder takes nothing returns boolean
local unit U = GetTriggerUnit()
local CursorData C = CursorData[GetOwningPlayer(U)]
if GetIssuedOrderId() == OrderId(CAST_ORDERSTRING) and GetUnitAbilityLevel(U, CursorTypeAbilities[C.CursorType]) > 0 then
call BJDebugMsg("...click...")
call PauseTimer(C.T)
call ReleaseTimer(C.T)
set C.T = null
call UnitRemoveAbility(C.Source, CANCEL_DETECTION_ABILITY)
call PauseUnit(U, true)
call IssueImmediateOrder(U, "stop")
call PauseUnit(U, false)
if C.ClickFunc.evaluate(C.P, C.Source, GetOrderPointX(), GetOrderPointY(), GetOrderTarget()) then
call UnitRemoveAbility(C.Source, CursorTypeAbilities[C.CursorType])
elseif GetLocalPlayer() == C.P then
call ForceUIKey(CAST_HOTKEY)
endif
endif
set U = null
return false
endfunction
private function PrematureCancel takes CursorData C returns nothing
call PauseTimer(C.T)
call ReleaseTimer(C.T)
set C.T = null
call UnitRemoveAbility(C.Source, CANCEL_DETECTION_ABILITY)
call UnitRemoveAbility(C.Source, CursorTypeAbilities[C.CursorType])
call C.CancelFunc.execute(C.P, C.Source)
endfunction
private function Periodic takes nothing returns nothing
local CursorData C = CursorData(GetTimerData(GetExpiredTimer()))
call BJDebugMsg("Periodic")
if not C.Ignore then
if GetWidgetLife(C.Source) < 0.406 then
call PrematureCancel(C)
else
if GetLocalPlayer() == C.P then
call ForceUIKey(CANCEL_DETECTION_HOTKEY)
endif
endif
else
if GetLocalPlayer() == C.P then
call ForceUIKey(CAST_HOTKEY)
endif
set C.Ignore = false
endif
endfunction
function ShowCursor takes player whichPlayer, unit sourceUnit, integer cursorType, CursorClick clickFunc, CursorCancel cancelFunc, boolean overWrite returns boolean
local CursorData C = CursorData[whichPlayer]
if C.T == null then
set C.T = NewTimer()
set C.Source = sourceUnit
set C.ClickFunc = clickFunc
set C.CancelFunc = cancelFunc
set C.CursorType = cursorType
call SetTimerData(C.T, C)
elseif not overWrite then
return false
endif
if GetUnitAbilityLevel(sourceUnit, CANCEL_DETECTION_ABILITY) == 0 then
call UnitAddAbility(sourceUnit, CANCEL_DETECTION_ABILITY)
call UnitMakeAbilityPermanent(sourceUnit, true, CANCEL_DETECTION_ABILITY)
endif
if GetUnitAbilityLevel(sourceUnit, CursorTypeAbilities[cursorType]) == 0 then
call UnitAddAbility(sourceUnit, CursorTypeAbilities[cursorType])
call UnitMakeAbilityPermanent(sourceUnit, true, CursorTypeAbilities[cursorType])
set C.Ignore = true
elseif GetLocalPlayer() == whichPlayer then
call ForceUIKey(CAST_HOTKEY)
endif
if GetLocalPlayer() == whichPlayer then
call SelectUnit(sourceUnit, false)
call SelectUnit(sourceUnit, true)
endif
call TimerStart(C.T, CANCEL_PERIOD, true, function Periodic)
return true
endfunction
private function Init takes nothing returns nothing
local integer J = 0
loop
set CDArray[J] = CursorData.create()
set CDArray[J].P = Player(J)
set J = J+1
exitwhen J >= 12
endloop
call CursorInit()
set CancelTrig = CreateTrigger()
call TriggerRegisterAnyUnitEventBJ(CancelTrig, EVENT_PLAYER_UNIT_ISSUED_ORDER)
call TriggerAddCondition(CancelTrig, Condition(function OnCancelOrder))
set ClickTrig = CreateTrigger()
call TriggerRegisterAnyUnitEventBJ(ClickTrig, EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER)
call TriggerRegisterAnyUnitEventBJ(ClickTrig, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER)
call TriggerAddCondition(ClickTrig, Condition(function OnClickOrder))
endfunction
endlibrary
And attached is a testmap. Type "-" to initiate a cursor display. Every time you click a wisp should appear at the clicked location. Whenever you cancel the sequence (or the system detects a cancel), the wisps will disappear. |
