Couple (v)JASS questions...

//=======================================
// KILLING SLOW
// This script makes a normal sorceress slow spell killing.
//========================================

// Scopes allow for better control over code (public/private/globals).
scope MySpell

// Note how this function is private.
// No code outside this scope is supposed to be able to access it.
private function Actions takes nothing returns nothing

  // As said, a very simple spell.
  // Kills the target of the spell.
    call KillUnit( GetSpellTargetUnit() )
endfunction

// Note that this function is supposed to return a boolean.
private function Conditions takes nothing returns boolean

  // If the casted spell equals to slow, then
  // return 'Also' == 'Aslo' ( = true )
  // This let's the system know that the condition is true
  // and that we can run the trigger actions.
    return GetSpellAbilityId() == 'Aslo'

  // PS. 'Aslo' is an ability rawcode (Slow, in this case).
  // Go to the Object Editor and press Ctrl+D to see rawcodes.
endfunction

//===========================================================================
// A PUBLIC function named InitTrig (inside a scope)
// will always be run at map init.
// This is where we set up the trigger.
public function InitTrig takes nothing returns nothing
    local trigger trg = CreateTrigger()

  // If any unit begins the effect of any spell...
  // (triggers exactly when the spell is cast)
    call TriggerRegisterAnyUnitEventBJ(trg,EVENT_PLAYER_UNIT_SPELL_EFFECT)

  // Check for what spell it was...
    call TriggerAddCondition(trg,Condition(function Conditions))

  // If the Condition was true, run the function Actions!
    call TriggerAddAction(trg, function Actions )

  // This might be unnecessary, but I like it ^^
    set trg=null
endfunction

endscope

scope MySpell

private function Actions takes nothing returns nothing
    call KillUnit( GetSpellTargetUnit() )
endfunction

private function Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'Aslo'
endfunction

public function InitTrig takes nothing returns nothing
    local trigger trg = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(trg,EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(trg,Condition(function Conditions))
    call TriggerAddAction(trg, function Actions )
    set trg=null
endfunction

endscope

//=======================================
// DAMAGING SLOW
// This script makes a normal sorceress slow damage the target
// for 200 damage after 5 seconds.
//========================================

scope MySpell

// No other code is supposed to make instances of this struct.
// Hence, its private:
private struct Data

  // After 5 seconds have passed, we no longer have the original variables.
  // We need to know caster and target to be able to deal damage!
    unit target
    unit caster

  // PS. For hero spells, you could also store things that may vary over level, like:
  //  integer damage
endstruct

// Here's the function that will be run when a timer expires.
// Stuff like GetSpellTargetUnit and GetSpellAbilityUnit are forgotten.
// The only thing this function knows is GetExpiredTimer()
// Luckily we have attached a Data-instance to the timer.
private function End takes nothing returns nothing

  // Retrieve the Data instance associated with this timer.
    local Data d = Data( GetTimerData( GetExpiredTimer() ) )

  // Here it comes...!
  // d.caster shall damage d.target for 200 damage
  // The booleans are usually set that way (true,false)
  // Spell Damage = ATTACK_TYPE_NORMAL
  // Damage and weapon type are somewhat tricky.
  // In most cases, you'll be fine with normal and whoknows.
    call UnitDamageTarget(d.caster,d.target,200,true,false,ATTACK_TYPE_NORMAL,DAMAGE_TYPE_NORMAL,WEAPON_TYPE_WNOKNOWS)

  // Clean up and destroy the struct instance:
    set d.target = null
    set d.caster = null
    call d.destroy()

  // Return the timer to TimerUtils
    call ReleaseTimer( GetExpiredTimer() )
endfunction

private function Actions takes nothing returns nothing

  // Obtain the timer from TimerUtils
  // We need a timer to wait 5 seconds
  // Normal Wait/TriggerSleepAction isn't good.
    local timer t = NewTimer()

  // Create a new instance of the struct:
    local Data d = Data.create()

  // The the instance's variables...
    set d.caster = GetSpellAbilityUnit()
    set d.target = GetSpellTargetUnit()

  // Associate your data instance with this timer:
    call SetTimerData(t,d)

  // Start your timer (t).
  // Let it expire in 5 seconds.
  // It should not be looping (false)
  // When it expires, the function End will be run.
    call TimerStart(t,5,false,function End)

  // Is this unnecessary too? Perhaps..
    set t=null
endfunction


private function Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'Aslo'
  // PS. 'Aslo' is an ability rawcode (Slow, in this case).
  // Go to the Object Editor and press Ctrl+D to see rawcodes.
endfunction

//===========================================================================
public function InitTrig takes nothing returns nothing
    local trigger trg = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(trg,EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(trg,Condition(function Conditions))
    call TriggerAddAction(trg, function Actions )

  // This might be unnecessary, but I like it ^^
    set trg=null
endfunction

endscope

scope B initializer A

public function InitTrig takes nothing returns nothing