Request: Shield System

  struct armour extends DamageModifier
      // All additional struct members are optional:
      static integer PRIORITY=0 // Default priority
      real power // This lets us give different units differently strong armour.
  
      // create method is optional, if you don't declare one then you must use
      // the .allocate parameters (unit, integer) when creating a modifier of this kind.
      static method create takes unit u, real power returns armour
          // Note the parameters for .allocate, this is because this struct extends
          // DamageModifier which asks for these parameters in its create method:
          local armour this = armour.allocate(u, armour.PRIORITY)
          set this.power = power
          return this
      endmethod

      // This is the method that runs when damage is dealt to the unit with the modifier.
      // The damage parameter tells how much damage got to this modifier past any modifiers
      // with a higher priority that the unit may have.
      // The value that the method returns tells the system by how much to modify the damage,
      // a positive return value increases damage while a negative value reduces it.
      method onDamageTaken takes unit damageSource, real damage returns real
          // This is a simple modifier that just gives a flat damage reduction.
          if this.power>damage then
              return -damage
          endif
          return -this.power
      endmethod
      // There is no onDamageDealt method so this modifier does not affect the damage that the unit deals.
      // onDestroy method is optional, in this case we don't need it.
  endstruct

// Simply add an armour to a unit using the create method:
  call armour.create(u, 10) // Gives unit u 10 armour.

  struct shield extends DamageModifier
      real hp
  
      static method create takes unit u, real shieldhp, integer priority returns shield
          local shield this = shield.allocate(u, priority)
          set this.hp = shieldhp
          return this
      endmethod

      method onDamageTaken takes unit damageSource, real damage returns real
          if this.hp>damage then
              set this.hp=this.hp-damage
          else
              set damage=this.hp
              call this.destroy()
          endif
          return -damage
      endmethod
  endstruct

  struct shield extends DamageModifier
      real hp
      real factor
      boolean limited
  
      static method create takes unit u, real shieldhp, real blockfactor, integer priority returns shield
          local shield this = shield.allocate(u, priority)
          set this.hp = shieldhp
          set this.limited=not(shieldhp==0.0)
          set this.factor = blockfactor
          return this
      endmethod

      method onDamageTaken takes unit damageSource, real damage returns real
          set damage=damage*factor
          if this.limited then
              if this.hp>damage then
                  set this.hp=this.hp-damage
              else
                  set damage=this.hp
                  call this.destroy()
              endif
          endif
          return -damage
      endmethod
  endstruct

  struct shield extends DamageModifier
      real hp
      real maxhp
      real regen
      real factor
      boolean limited
      timer t

      static real REGEN_PERIOD = 0.1

      static method regenerate takes nothing returns nothing
          local shield this = shield(GetTimerData( GetExpiredTimer() ))
          set this.hp=this.hp+this.regen*shield.REGEN_PERIOD
          if this.hp>this.maxhp then
              set this.hp=this.maxhp
          endif
      endmethod
  
      static method create takes unit u, real shieldhp, real hpregen, real blockfactor, integer priority returns shield
          local shield this = shield.allocate(u, priority)
          set this.hp = shieldhp
          set this.maxhp = shieldhp
          set this.regen = hpregen
          set this.limited=not(shieldhp==0.0)
          set this.factor = blockfactor
          set this.t=NewTimer()
          call SetTimerData( this.t, integer(this) )
          call TimerStart( this.t, shield.REGEN_PERIOD, true, function shield.regenerate )
          return this
      endmethod

      method onDamageTaken takes unit damageSource, real damage returns real
          set damage=damage*factor
          if this.limited then
              if this.hp>damage then
                  set this.hp=this.hp-damage
              else
                  set damage=this.hp
                  call this.destroy()
              endif
          endif
          return -damage
      endmethod

      method onDestroy takes nothing returns nothing
          call ReleaseTimer( this.t )
      endmethod
  endstruct