Int2Word

// ============================================================================
// Int2Word - By Ammorth                                         Jan 29, 2009
//   **Requires JassHelper (vJass) to compile**        
//   Thanks to Grim001 for the improved version (less comparisons).
//
// use Int2Word(integer) to get a string of the integer passed.
// Can handle any signed 32 bit number (what wc3 uses), including negatives.
//
// User Function:
//     function Int2Word takes integer i returns string
//
// set message = Int2Word(8342)
// call BJDebugMsg(message) // displays "eight thousand three hundred forty-two"
//
// set message = Int2Word(-10000)
// call BJDebugMsg(message) // displays "negative ten thousand"
//
// =============================================================================
library Int2Word initializer onInit

    globals
        private string array zero
        private string array space
        private string array basic // stores the basic values
        private string array dashbasic // stores the basic values with dashes
        private string array tens // stores the tens
        private constant string hundred = " hundred" // needs leading space for formatting
        private constant string thousand = " thousand" // needs leading space for formatting
        private constant string million = " million" // needs leading space for formatting
        private constant string billion = " billion" // needs leading space for formatting
        private constant string negative = "negative " // needs trailing space for formatting
        private constant integer Zero = 0
        private constant integer NoZero = 1
        private constant integer Space = 0
        private constant integer NoSpace = 1
    endglobals
    
    function Int2Word_Sub takes integer i, integer z, integer s returns string
            if i == 0 then
                return zero[z] //returns null string if Zero != 0
            elseif i < 0 then // add negative to the front and get the words for the positive value
                return negative+Int2Word_Sub(-i, NoZero, NoSpace)
            elseif i < 20 then // we can handle these with a simple array lookup
                return space[s]+basic[i]
            elseif i < 100 then // under 100
                return space[s]+tens[i / 10]+dashbasic[i - (i / 10)*10] 
            elseif i < 1000 then // under 1000
                return space[s]+basic[i / 100]+hundred+Int2Word_Sub(i - (i / 100)*100, NoZero, Space)
            elseif i < 1000000 then // under a million
                return space[s]+Int2Word_Sub(i / 1000, NoZero, NoSpace)+thousand+Int2Word_Sub(i - (i / 1000)*1000, NoZero, Space)
            elseif i < 1000000000 then // under a billion
                return space[s]+Int2Word_Sub(i / 1000000, NoZero, NoSpace)+million+Int2Word_Sub(i - (i / 1000000)*1000000, NoZero, Space)
            endif // a billion and up...
        return space[s]+basic[i/1000000000]+billion+Int2Word_Sub(i - (i / 1000000000)*1000000000, NoZero, Space)
    endfunction
    
    function Int2Word takes integer i returns string
        return Int2Word_Sub(i, Zero, NoSpace)
    endfunction
    
    private function onInit takes nothing returns nothing
        set zero[0] = "zero"
        set space[0] = " "
        set basic[0] = "" // the basic numbers
        set basic[1] = "one"
        set basic[2] = "two"
        set basic[3] = "three"
        set basic[4] = "four"
        set basic[5] = "five"
        set basic[6] = "six"
        set basic[7] = "seven"
        set basic[8] = "eight"
        set basic[9] = "nine"
        set basic[10] = "ten"    // isn't included in tens, since the teens have some oddities
        set basic[11] = "eleven" // that require them to be in the basic section (damn english)
        set basic[12] = "twelve"
        set basic[13] = "thirteen"
        set basic[14] = "fourteen"
        set basic[15] = "fifteen"
        set basic[16] = "sixteen"
        set basic[17] = "seventeen"
        set basic[18] = "eighteen"
        set basic[19] = "nineteen"
        set dashbasic[0] = ""
        set dashbasic[1] = "-one"
        set dashbasic[2] = "-two"
        set dashbasic[3] = "-three"
        set dashbasic[4] = "-four"
        set dashbasic[5] = "-five"
        set dashbasic[6] = "-six"
        set dashbasic[7] = "-seven"
        set dashbasic[8] = "-eight"
        set dashbasic[9] = "-nine"
        set tens[2] = "twenty" // now we can count by tens
        set tens[3] = "thirty"
        set tens[4] = "forty"
        set tens[5] = "fifty"
        set tens[6] = "sixty"
        set tens[7] = "seventy"
        set tens[8] = "eighty"
        set tens[9] = "ninety"
    endfunction
endlibrary