HCL code vjass -> jass

// !! THIS IS NOT AN OFFICAL COPY OF HCL !!
//
// This is an unoffical port of HCL by Strilanc, to Jass.
// This is ported from v1.01
// The official HCL library can be found here:
// [url]http://www.wc3c.net/showthread.php?t=106854[/url]
//
// !! THIS IS NOT AN OFFICAL COPY OF HCL !!


///////////////////////////////////////////
/// HostBot Command Library
/// Last Modified: September 14, 2009
/// Authors: Strilanc, 
/// v1.01
///////////////////////////////////////////
/// Reads a command string transparently encoded into player handicaps by hostbots.
/// Allows at most one character from "abcdefghijklmnopqrstuvwxyz0123456789 -=,." per player.
/// Empty slots don't count towards the player count, but computers do.
///////////////////////////////////////////

// Setup:  1) Copy this script to the custom script section of your map.
//         2) Create a string variable called HCL_command with initial value "" (empty string)
//         3) Create a trigger on Map Initialization that has the following action:
//            Custom Script:  call HCL_init()
//         4) You can now get the string either through the HCL_command variable created
//            or through HCL_GetCommandString()
    
    function HCL_GetCommandString takes nothing returns string
        return udg_HCL_command
    endfunction
    
    function HCL_init takes nothing returns nothing
        local integer i
        local integer j
        local integer h
        local integer v
        local string chars= "abcdefghijklmnopqrstuvwxyz0123456789 -=,."
        local integer array map
        local boolean array blocked

        //precompute mapping [have to avoid invalid and normal handicaps]
        set blocked[0]=true
        set blocked[50]=true
        set blocked[60]=true
        set blocked[70]=true
        set blocked[80]=true
        set blocked[90]=true
        set blocked[100]=true
        set i=0
        set j=0
        loop
            if blocked[j] then
                set j=j + 1
            endif
            exitwhen j >= 256
            set map[j]=i
            set i=i + 1
            set j=j + 1
        endloop
        
        //Extract command string from player handicaps
        set i=0
        loop
            exitwhen i >= 12
            set h=R2I(100 * GetPlayerHandicap(Player(i)) + 0.5)
            if not blocked[h] then
                set h=map[h]
                set v=h / 6
                set h=h - v * 6
                call SetPlayerHandicap(Player(i), 0.5 + h / 10.0)
                set udg_HCL_command = udg_HCL_command + SubString(chars, v, v + 1)
            endif
            set i=i + 1
        endloop
    endfunction
    
// !! THIS IS NOT AN OFFICAL COPY OF HCL !!
//
// This is an unoffical port of HCL by Strilanc, to Jass.
// This is ported from v1.01
// The official HCL library can be found here:
// [url]http://www.wc3c.net/showthread.php?t=106854[/url]
//
// !! THIS IS NOT AN OFFICAL COPY OF HCL !!