[system] (vJass) CustomFilter

library CustomFilterExamples initializer all requires CustomFilter, CFLib, CFEnum

    //: ------------------------------------------------------------------------
    //: Lets do some basic stuff at first.
    private function e1 takes nothing returns nothing
        //: Create a new group
        local group g = CreateGroup()
        //: and lets use the alive filter
        call FILTER_UNIT_ALIVE.apply()
        //: and now lets enumerate units into the group.
        call GroupEnumUnitsInRange(g, 0., 0., 512., UNIT_FILTER)
        //: Lets do a little check if we picked any unit
        call BJDebugMsg("We picked " + I2S(CountUnitsInGroup(g)) + " units!")
    endfunction
    
    //: ------------------------------------------------------------------------
    //: Lets do something more advanced. We pick all units that are non-heroes
    //: and print them.
    private function e2_Print takes nothing returns nothing
        //: Notice how we can access to the global variable
        //: FILTER_UNIT at any place!
        call BJDebugMsg(GetUnitName(FILTER_UNIT))
    endfunction

    private function e2 takes nothing returns nothing
        local group g = CreateGroup()
        call FILTER_UNIT_NOT_HERO.apply()
        //: We actually need to link the enum with function
        //: Do this AFTER applying the filter!
        call setOnUnitEnum(e2_Print)
        call GroupEnumUnitsInRange(g, 0., 0., 512., UNIT_FILTER)
    endfunction
    
    //: ------------------------------------------------------------------------
    //: Lets do some advanced filtering this time. 
    //: Who wants all units to be filtered, everytime?
    //: To face it, we want only 10 units that are not undead.
    private function e3 takes nothing returns nothing
        local group g = CreateGroup()
        //: Notice how we can connect filters inside each other!
        local LimitedFilter lf = LimitedFilter.create(FILTER_UNIT_NOT_UNDEAD, 10)
        
        call lf.apply()
        call GroupEnumUnitsInRange(g, 0., 0., 512., UNIT_FILTER)
        call lf.destroy()
        
        //: Lets do a little check if we picked any unit
        call BJDebugMsg("We picked " + I2S(CountUnitsInGroup(g)) + " units!")
    endfunction
    
    //: ------------------------------------------------------------------------
    //: We still haven't concatigated conditions yet. 
    //: This time, we want to have an unit that is either dead or alive and 
    //: not an hero
    private function e4 takes nothing returns nothing
        local group g = CreateGroup()
        //: Notice how we can connect this two filters 
        //: with an AND connector.
        local AndFilter ad = AndFilter.create(FILTER_UNIT_ALIVE, FILTER_UNIT_HERO, false)
        //: Notice how we can now connect 2 filters 
        //: of different types with this or filter
        local OrFilter of = OrFilter.create(FILTER_UNIT_DEAD, ad)
        
        call of.apply()
        call GroupEnumUnitsInRange(g, 0., 0., 512., UNIT_FILTER)
        call of.destroy()
        call ad.destroy()
        
        //: Lets do a little check if we picked any unit
        call BJDebugMsg("We picked " + I2S(CountUnitsInGroup(g)) + " units!")
    endfunction
    
    //: ------------------------------------------------------------------------
    //: Now we want to do something more advanced.
    //: This time we want to have a filter for all units of a spell.
    //: The filter is for disentigrate from Diablo III, so we use the CFEnum
    //: library to get new, great enumeration functions.
    //: For this spell we want to have alive units only, that are enemies.
    globals
        private constant real DISINTEGRATE_RANGE = 128.
    endglobals
    
    private struct e5struct
        private unit caster = null
        private real x1 = 0.
        private real y1 = 0.
        private real x2 = 0.
        private real y2 = 0.
        
        private method dmg takes nothing returns nothing
            local real lastHp = GetUnitState(FILTER_UNIT, UNIT_STATE_LIFE)
            local real newHp = lastHp - 25.
            
            call SetUnitState(FILTER_UNIT, newHp)
        endmethod
        
        //: This is the method that is run every few ms.
        private method e5 takes nothing returns nothing
            local group g = CreateGroup()
            //: Create a new allyfilter
            local AllyFilter af = AllyFilter.create(GetOwningPlayer(.caster), false)
            //: Create a new andfilter and connect it with ally and alivefilter
            local AndFilter andf = AndFilter.create(af, FILTER_UNIT_ALIVE, false)
            
            call andf.apply()
            //: Notice how we again connect enumeration with method calls.
            call setOnUnitEnum(.dmg)
            //: Function of the CFLib
            call EnumUnitsInRangeOfLine(g, .x1, .y1, .x2, .y2, DISINTEGRATE_RANGE)
            call andf.destroy()
            call af.destroy()
        endmethod
    endstruct
    
    //: ------------------------------------------------------------------------
    //: Lets use our own condition functions.
    private function e6_Print takes nothing returns nothing
        //: Notice how we can access to the global variable
        //: FILTER_UNIT at any place!
        call BJDebugMsg(GetUnitName(FILTER_UNIT))
    endfunction
    
    private function e6_Cond takes nothing returns boolean
        return GetUnitState(FILTER_UNIT, UNIT_STATE_LIFE) >= 100.
    endfunction
    
    private function e6 takes nothing returns nothing
        local group g = CreateGroup()
        //: Lets filter all units (TRUE_FILTER) that match our condition
        local CondFilter cf = UnitCondFilter.create(TRUE_FILTER, e6_Cond, false)
        
        call cf.apply()
        //: Notice how we again connect enumeration with method calls.
        call setOnUnitEnum(e6_Print)
        call GroupEnumUnitsInRange(g, 0., 0., 512., UNIT_FILTER)
        call cf.destroy()
        //: Thats it. Was is that hard?
    endfunction
    
    //: ------------------------------------------------------------------------
    //: Now you know about a lot of functionality of this system.
    //: Thanks for downloading and using.
    //: ------------------------------------------------------------------------
    
    private function all takes nothing returns nothing
        call e1()
        //call e2()
        //call e3()
        //call e4()
        //call e5struct.create().e5()
        //call e6()
    endfunction
endlibrary

// Enumerate alive units that are non-heroes please!
local AndFilter af = AndFilter.create(FILTER_UNIT_ALIVE, FILTER_UNIT_NOT_HERO, false)
// Don't exceed the limit of 2.
local LimitedFilter lf = LimitedFilter.create(af, 2)

call lf.apply()
//Do enumeration

lf.destroy()
af.destroy()