Particle System

// Needs variable: forceGravity (integer)
function G takes nothing returns integer
  if udg_forceGravity == 0 then
    set udg_forceGravity = VectorCreate(0,0,-2500)
  endif
  return udg_forceGravity
endfunction

// Needs variable conditionGroundHit (trigger)
function ParticleGroundHitCond takes nothing returns boolean
  local unit u = GetEnumUnit()
  local location loc = GetUnitLoc(u)
  local integer i = udg_clsParticlePlace[GetUnitUserData(u)]

  if GetLocationZ(loc) > udg_vectorZ[i] then
    call RemoveLocation(loc)
    set loc = null
    return true
  endif

  call RemoveLocation(loc)
  set loc = null
  return false
endfunction
function ParticleGroundHit takes nothing returns trigger
  if udg_conditionGroundHit == null then
    set udg_conditionGroundHit = CreateEvalTrig(function ParticleGroundHitCond)
  endif
  return udg_conditionGroundHit
endfunction

// Needs variable conditionDeath (trigger)
function ParticleDeathCond takes nothing returns boolean
  return GetWidgetLife(GetEnumUnit()) < 0.405
endfunction
function ParticleDeath takes nothing returns trigger
  if udg_conditionDeath == null then
    set udg_conditionDeath = CreateEvalTrig(function ParticleDeathCond)
  endif
  return udg_conditionDeath
endfunction

// needs an extra variable: udg_TUnit (unit), can hit allies to, add a condition to the group otherwise
function ParticleCollisionCond takes nothing returns boolean
  local group g = CreateGroup()
  local unit u = GetEnumUnit()
  local unit f
  local integer p = udg_clsParticlePlace[GetUnitUserData(u)]
  local integer tv
  local location l
  call GroupEnumUnitsInRange(g, udg_vectorX[p], udg_vectorY[p], 60, null)

  loop
    set f = FirstOfGroup(g)
    exitwhen f == null
    set l = GetUnitLoc(f)
    set tv = VectorCreate(GetLocationX(l), GetLocationY(l), GetLocationZ(l)+GetUnitFlyHeight(f))
    call RemoveLocation(l)

    if IsPointInSphere(tv, p, 60) then

      call VectorDestroy(tv)

      set udg_TUnit = f //This is a temp global to be used in the conditionfuncs

      set u = null
      set l = null
      set f = null

      return true
    endif
    call VectorDestroy(tv)
    call GroupRemoveUnit(g,f)
  endloop

  set u = null
  set l = null
  set f = null

  return false
endfunction
function ParticleCollision takes nothing returns trigger
  if udg_conditionCollision == null then
    set udg_conditionCollision = CreateEvalTrig(function ParticleCollisionCond)
  endif
  return udg_conditionCollision
endfunction

// Bounces a particle back up. This function works on both flat and angled terrain.
function GroundHit_Bounce takes nothing returns nothing
  local unit u = GetEnumUnit()
  local integer i = GetUnitUserData(u)
  local integer p = udg_clsParticlePlace[i]
  local integer v = udg_clsParticleSpeed[i]
  local integer vector1 = VectorGetTerrainNormal(udg_vectorX[p], udg_vectorY[p], 25.0)
  local integer vector2 = VectorProjectVector(v,vector1)

  set udg_vectorX[p] = udg_vectorX[p] - udg_vectorX[v]*ParticlePeriod()
  set udg_vectorY[p] = udg_vectorY[p] - udg_vectorY[v]*ParticlePeriod()
  set udg_vectorZ[p] = udg_vectorZ[p] - udg_vectorZ[v]*ParticlePeriod()

  call VectorScale(vector2, -2)
  call VectorAdd(v, vector2)
  call VectorScale(v, 0.65)

  call VectorDestroy(vector1)
  call VectorDestroy(vector2)
  set u = null
endfunction


// damages the target (used in CollisionDamage condition) for 10 hp.
function Collision_Damage10 takes nothing returns nothing
  local unit u = GetEnumUnit()
  call UnitDamageTarget(u, udg_TUnit, 10, true, false, ATTACK_TYPE_CHAOS, DAMAGE_TYPE_NORMAL, WEAPON_TYPE_WHOKNOWS)
  call DestroyEffect(AddSpecialEffectTarget("bloodeffect?", udg_TUnit, "chest")) //replace "bloodeffect?" with the path of a blood effect, you can also leave out this part.
  call KillUnit(u)
  call RemoveParticle(u,true)
  set u = null
endfunction