Spear of Longinus

04-07-2008, 12:35 PM

Ok, submission time....

The Spear of Longinus
By moyack

Requires JASS NEW GEN pack 5B or up. Totally MUI, and made with vJASS.

Spell type: Passive (buff dependant)

Description: The Spear of Longinus is known for being a weapon blessed by the Gods, giving to its owner astonishing strength and deadly results. Every time the owner of this mighty spear attacks, it has a chance to deal additional damage to the target unit, impaling them and throwing away a long distance.

Additionally if there are units behind them, this spear will impale them with the target unit.

Level 1: low chance to cast the ability, up to 3 units impaled, deals 100 damage to each impaled unit, consumes 10 mana.
Level 2: medium chance to cast the ability, up to 4 units impaled, deals 150 damage to each impaled unit, consumes 8 mana.
Level 3: high chance to cast the ability, up to 5 units impaled, deals 200 damage to each impaled unit, consumes 6 mana.

Changelog

Current code:

//*****************************************************************
//*                     THE SPEAR OF LONGINUS                     *
//*            Spell created for the Spell Contest #10            *
//*                      at WC3Campaigns.net                      *
//*                                                               *
//*                           By moyack                           *
//*                             V 2.0                             *
//*****************************************************************

scope Longinus initializer init
//***************
// CONFIGURATION
//***************
globals
    private constant integer SpellID = 'A000' //Spell ID
    private constant integer BuffID  = 'B000' //Buff ID
    private constant integer DummyID = 'n000' //Dummy unit ID.
    private constant real    Height  = 100.   //Sets the missile height
    private constant real    dt      = 0.034  //Sets the timer duration.
    private constant real    Speed   = 900.   //Sets this value equal to the value of the unit missile speed.
    private constant real    Radius  = 90.    //Sets the range in which the projectile will catch other units
    private constant real    Sep     = 50.    //Sets the separation distance between impaled units.
    private constant real    Scale   = 2.     //Sets the spear model scale.
    private constant real    Cooldwn = 0.8    //Sets the attack animation cooldown. The purpose of this value is that the hero can't abuse of this ability, if it's set to 0, the hero could cast this spell too many times with one attack.
endglobals

// sets the damage of each attack
private constant function Damage takes integer l returns real 
    return 100. + 50. * (l - 1)
endfunction

// sets the chance to use the spell
private constant function Chance takes integer l returns real 
    return 0.3 + 0.3 * (l - 1)
endfunction

// sets the max distance that are throwed the affected units
private constant function MaxDist takes integer l returns real 
    return 800. + 100. * (l - 1)
endfunction

// sets the max number of units which are impaled by the spear
private constant function Impaled takes integer l returns integer 
    return 3 + 1 * (l - 1)
endfunction

// sets the mana consumed per effective casting
private constant function Mana takes integer l returns real 
    return 10. - 2. * (l - 1)
endfunction

// Change this function in order to catch all the units that can be impaled by the spear
private function GetUnits takes nothing returns boolean
    return IsUnitType(GetFilterUnit(), UNIT_TYPE_MECHANICAL) == false and GetWidgetLife(GetFilterUnit()) > 0.405
endfunction
//*******************
// END CONFIGURATION
//*******************

globals
    // please DO NOT TOUCH this part if you don't know what are you doing!!!
    private group    G = CreateGroup()
    private region   R
    private rect     T
    private string   SonicFX
    private string   BloodFX
endglobals

private keyword Data

private constant function True takes nothing returns boolean
    return true
endfunction

private function CountDest takes nothing returns nothing
    set bj_forceCountPlayers = bj_forceCountPlayers + 1
endfunction

private function MoveImpaled takes nothing returns nothing
    local Data D = Data(bj_destInRegionDiesCount)
    call SetUnitX(GetEnumUnit(), GetUnitX(D.dummy) + Sep * bj_groupCountUnits * D.cos)
    call SetUnitY(GetEnumUnit(), GetUnitY(D.dummy) + Sep * bj_groupCountUnits * D.sin)
    call MoveRectTo(T, GetUnitX(GetEnumUnit()), GetUnitY(GetEnumUnit()))
    set bj_forceCountPlayers = 0
    call EnumDestructablesInRect(T, Condition(function True), function CountDest)
    if not IsUnitInRegion(R, GetEnumUnit()) or bj_forceCountPlayers > 0 then
        call D.clean()
    endif
    set bj_groupCountUnits = bj_groupCountUnits + 1
endfunction

private function DealDamage takes nothing returns nothing
    local Data D = Data(bj_destInRegionDiesCount)
    if IsUnitInRangeXY(GetEnumUnit(), GetUnitX(D.dummy) + Radius * D.cos, GetUnitY(D.dummy) + Radius * D.sin, Radius) and not IsUnitInGroup(GetEnumUnit(), D.Units) then
        call UnitDamageTarget(D.caster, GetEnumUnit(), Damage(GetUnitAbilityLevel(D.caster, SpellID)), true, true, ATTACK_TYPE_PIERCE, DAMAGE_TYPE_NORMAL, WEAPON_TYPE_CLAW_HEAVY_SLICE)
        call DestroyEffect(AddSpecialEffectTarget(BloodFX, GetEnumUnit(), "chest"))
        call PauseUnit(GetEnumUnit(), true)
        call GroupAddUnit(D.Units, GetEnumUnit())
        set D.count = D.count + 1
    endif
endfunction

interface Updater
    method Update takes nothing returns nothing
endinterface

private struct indexer extends Updater
    static timer T = CreateTimer()
    static integer counter = 0
    static indexer array indexers
    integer i
    boolean on = true
    
    private method Update takes nothing returns nothing
        debug call DisplayTimedTextFromPlayer(GetLocalPlayer(), 0,0,2, "Dummy update function has been executed...")
    endmethod
    
    static method DoUpdate takes Updater U returns nothing
        call U.Update()
    endmethod
    
    method onDestroy takes nothing returns nothing
        set indexer.counter = indexer.counter - 1
        set indexer.indexers[indexer.counter].i = .i
        set indexer.indexers[.i] = indexer.indexers[indexer.counter]
        if indexer.counter < 1 then
            call PauseTimer(indexer.T)
        endif
        set .on = false
    endmethod
    
    private static method Loop takes nothing returns nothing
        local integer i = 0
        loop
            exitwhen i > indexer.counter
            call indexer.DoUpdate(indexer.indexers[i])
            set i = i + 1
        endloop
    endmethod
    
    static method create takes nothing returns indexer
        local indexer I = indexer.allocate()
        set I.i = indexer.counter
        set indexer.indexers[indexer.counter] = integer(I)
        set indexer.counter = indexer.counter + 1
        if indexer.counter == 1 then
            call TimerStart(indexer.T, dt, true, function indexer.Loop)
        endif
        return I
    endmethod
endstruct

private struct cooldown extends indexer
    private static group Cool = CreateGroup()
    unit u
    real time = 0.
    real dur
    
    static method start takes unit u, real dur returns nothing
        local cooldown C
        local integer i = 1
        if not IsUnitInGroup(u, .Cool) then
            call GroupAddUnit(.Cool, u)
            set C = cooldown.allocate()
            set C.u = u
            set C.dur = dur
        endif
    endmethod
    
    method onDestroy takes nothing returns nothing
        call GroupRemoveUnit(cooldown.Cool, .u)
        set .u = null
    endmethod
    
    private method Update takes nothing returns nothing
        set .time = .time + dt
        if .time >= .dur  and .on then
            call .destroy()
        endif
    endmethod
    
    static method IsInCooldown takes unit u returns boolean
        return IsUnitInGroup(u, .Cool)
    endmethod
endstruct

private struct Data extends indexer
    unit caster
    unit dummy
    group Units
    integer count = 0
    real angle
    real cos
    real sin
    real dist = 0.
    
    static method Start takes unit caster, unit target returns nothing
        local Data D = Data.allocate()
        if D.Units == null then
            set D.Units = CreateGroup()
        endif
        set D.caster = caster
        set D.angle = Atan2(GetUnitY(target)-GetUnitY(caster), GetUnitX(target)-GetUnitX(caster))
        set D.cos = Cos(D.angle)
        set D.sin = Sin(D.angle)
        set D.dummy = CreateUnit(GetOwningPlayer(caster), DummyID, GetUnitX(caster) + Radius * D.cos, GetUnitY(caster) + Radius * D.sin, D.angle * bj_RADTODEG)
        call UnitAddAbility(D.dummy, 'Amrf')
        call SetUnitScale(D.dummy, Scale, Scale, Scale)
        call SetUnitFlyHeight(D.dummy, Height, 0.)
        call DestroyEffect(AddSpecialEffectTarget(SonicFX, D.dummy, "origin"))
    endmethod
    
    private static method Release takes nothing returns nothing
        call PauseUnit(GetEnumUnit(), false)
        call SetUnitPosition(GetEnumUnit(), GetUnitX(GetEnumUnit()), GetUnitY(GetEnumUnit()))
    endmethod
    
    private method onDestroy takes nothing returns nothing
        call ForGroup(.Units, function Data.Release)
        call RemoveUnit(.dummy)
        set .caster = null
        set .dummy = null
        call GroupClear(.Units)
    endmethod
    
    private method Update takes nothing returns nothing
        set .dist = .dist + Speed * dt
        if .dist > MaxDist(GetUnitAbilityLevel(.caster, SpellID)) and .on then
            call .destroy()
        else
            call SetUnitX(.dummy, GetUnitX(.dummy) + Speed * dt * .cos)
            call SetUnitY(.dummy, GetUnitY(.dummy) + Speed * dt * .sin)
            call GroupEnumUnitsInRange(G, GetUnitX(.dummy), GetUnitY(.dummy), Radius, Condition(function GetUnits))
            call GroupRemoveUnit(G, .caster)
            set bj_destInRegionDiesCount = integer(this)
            set bj_groupCountUnits = 0
            if .count < Impaled(GetUnitAbilityLevel(.caster, SpellID)) then
                call ForGroup(G, function DealDamage)
            endif
            call ForGroup(.Units, function MoveImpaled)
            call GroupClear(G)
        endif
    endmethod
    
    method clean takes nothing returns nothing
        set .dist = 2 * MaxDist(GetUnitAbilityLevel(.caster, SpellID))
    endmethod
endstruct

private function Actions takes nothing returns boolean
    if GetUnitAbilityLevel(GetAttacker(), BuffID) > 0 and GetRandomReal(0., 1.) < Chance(GetUnitAbilityLevel(GetAttacker(), SpellID)) and GetUnitState(GetAttacker(), UNIT_STATE_MANA) >= Mana(GetUnitAbilityLevel(GetAttacker(), SpellID)) and not cooldown.IsInCooldown(GetAttacker()) then
        call cooldown.start(GetAttacker(), Cooldwn)
        call Data.Start(GetAttacker(), GetTriggerUnit())
        call SetUnitState(GetAttacker(), UNIT_STATE_MANA, GetUnitState(GetAttacker(), UNIT_STATE_MANA) - Mana(GetUnitAbilityLevel(GetAttacker(), SpellID)))
    endif
    return false
endfunction

private function init takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ATTACKED)
    call TriggerAddCondition(t, Condition(function Actions))
    set T = Rect(0, Radius, 0, Radius)
    set R = CreateRegion()
    call RegionAddRect(R, bj_mapInitialPlayableArea)
    set SonicFX = GetAbilityEffectById(SpellID, EFFECT_TYPE_SPECIAL, 0) //Sonic effect model
    set BloodFX = GetAbilityEffectById(SpellID, EFFECT_TYPE_SPECIAL, 1) //Blood effect model
    call Preload(SonicFX)
    call Preload(BloodFX)
    set t = null
endfunction

endscope

Comments, suggestions are always welcome...

Attached Images

Clip_9.jpg (68.5 KB)

Attached Files

Longinus Spear.w3x (32.6 KB)

04-07-2008, 01:47 PM

Alexander244

I really enjoy spells which reward microing your hero, and this provided that in plenty.

Quick Feedback/Suggestions:

Sometimes if you are in very close melee with the target (you need to walk right up to them, closer than melee attack range) the spear misses them.
On effect you could add an item orb ability that changes missile art to nothing, so you don't sometimes get a double spear throw. Then remove it on attacks where no effect occurs.
You might even be able to use damage detection using this method and changing the missile art to the longinus spear, then only create the projectile on damage, which would look and work a lot better than the current method.
Because the ability costs mana, wouldn't it make sense for it to be toggleable on & off?
You could make it an arrow ability, or, if you want to leave it as a passive, do something similar to immolation.
onDestroy should be private

04-07-2008, 05:39 PM

moyack

Quote:

Originally Posted by Alexander244

I really enjoy spells which reward microing your hero, and this provided that in plenty.

Quick Feedback/Suggestions:
Sometimes if you are in very close melee with the target (you need to walk right up to them, closer than melee attack range) the spear misses them.

Hmm.... I'll check it out this night.

Quote:

On effect you could add an item orb ability that changes missile art to nothing, so you don't sometimes get a double spear throw. Then remove it on attacks where no effect occurs.

Actually a very good idea, I hadn't thought that solution :) I'll apply it this night too.

Quote:

You might even be able to use damage detection using this method and changing the missile art to the longinus spear, then only create the projectile on damage, which would look and work a lot better than the current method.

Well, I did it in this way in order to give the idea that the caster takes the spear and throws it to the enemy, so the attack event is the most accurate of all. Anyways, I'll check the orb effect and test how it looks, and, according to that I'd change the spell in concordance.

Quote:

Because the ability costs mana, wouldn't it make sense for it to be toggleable on & off?
You could make it an arrow ability, or, if you want to leave it as a passive, do something similar to immolation.

This spell requires mainly a buff to work, so any spell that left a buff in the caster can be perfectly used. For example, create a custom ability based on Berserk or immolation, set the chance to 100%, mana cost = 0 and set the buff in the spell, and voila!! an active spell.

Quote:

onDestroy should be private

hmmm.... yes, why not.

04-07-2008, 07:02 PM	#4
Salbrismind	I love this spell idea and I really want to use this in my map! All credit for it will go to you of course!

04-07-2008, 08:27 PM

Rising_Dusk

Quote:

Originally Posted by moyack

*I'll post the code when I get home...*

*Waits patiently because he doesn't have access to WE at work and isn't motivated enough to download and extract the testmap's .j file*

04-07-2008, 10:51 PM

Tide-Arc Ephemera

I cringed when I saw "The Spear of Longinus" (it's Lance), but that's only a minor detail.

... but just curious, what's the difference between vJass and Jass New Gen? I've been isolated from the whole coding concept for a while (and so I've regressed into GUI... but hoping to go back to JASS soon enough).

On the spell's notes, I found it was a lot of fun to play with, unique and I can see so many things this could be used as a base for.

04-07-2008, 10:54 PM	#7
darkwulfv	Jass New Gen is the pack name. vJASS is the extended language. On-Topic: Spell looks really cool. Well done.

04-07-2008, 10:54 PM

Rising_Dusk

Quote:

Originally Posted by Tide-Arc-Ephemera

... but just curious, what's the difference between vJass and Jass New Gen? I've been isolated from the whole coding concept for a while (and so I've regressed into GUI... but hoping to go back to JASS soon enough).

vJass is a syntactical add-on to typical WC3 jass, allowing many new and awesome things. Jass NewGen Pack is the pack that it comes bundled in (Alongside PJASS, grimoire, TESH, etc).

04-07-2008, 11:07 PM	#9
Tide-Arc Ephemera	Hm, I see. Would I still be able to use this spell without New Gen?

04-07-2008, 11:17 PM	#10
Rising_Dusk	If you could compile vJass in another way, sure, but JNGP is the cleanest, easiest, and furthest removed from hacking WE (again) way to do it.

04-08-2008, 02:17 AM

#11

moyack

Ok, updated the code and I've added other spell: Berserker Strength, which is the same code, but using an active ability based on Berserk. The purpose is to show how easy is to transform this ability into an active or toggleable one.

To be honest I couldn't try the option of removing the missile with a dummy orb ability. I've been so busy right now, and hardly I could post the code with some minor stuff.

04-09-2008, 01:25 AM	#12
Rising_Dusk	I have a feeling that your private constant functions will not compile correctly when inlined using Vex's optimizer. Just a heads up, since it's going to try to move that level argument into the actual function where it doesn't exist. I haven't the motivation right now to delve through it all in depth, but I'll get around to it soon. Promise! <3

04-10-2008, 03:22 PM	#13
moyack	What options are you using for optimization?? I'll try to check it this night.... if my energies allow me to do it.

04-10-2008, 05:29 PM	#14
Rising_Dusk	I didn't actually try it, but if my memory serves me correctly, constant functions and variables are inlined. If you have a constant function that is supposed to be changed, it would make sense for it to not work. I may be wrong though, but that's just what it seems like to me.

04-13-2008, 04:13 PM

#15

Vexorian

The constants are fine in this case. *checks map*

Try not to create objects during global declarations. It is not necessary for approval or anything but I advice agains it.

The spell needs fixing, the concept is nice but it is right now lacking in looks, the knockback + spear movement looks unrealistic. You should change your knockback so it doesn't just move the unit in the same direction as the spear, think of what happens to a potato bag when you try to push it in a straight line for long time, it will not obey you.