Attack Detect Fun!

library DamageDetection initializer Init uses PUI
// thanks to emjlr3 for showing me his OnAttack sys


globals
    //===========================================================================
    // Add only Conditions to this trigger, Actions will NOT be executed
    // Condition functions take nothing and return boolean
    // you should return false after your code
    // Do NOT use waits in Conditions
    //
    // EXAMPLE:
    // call TriggerAddCondition( GlobalOnDamageTrigger, Condition(function YourFunction) )
    //===========================================================================    
    trigger GlobalOnDamageTrigger

    private boolean array ignore // prevents requrzion
    private trigger array OnDamagePerUnit
endglobals


//===========================================================================
// GetTriggerUnit() - Damaged Unit (unit)
// GetEventDamage() - amount of damage (real)
// GetEventDamageSource() - what did the damage (unit), can be null ?

// Per Unit OnDamage events call this function,
// This function then calls global OnDamageTrigger
//===========================================================================
function OnDamage takes nothing returns boolean
    local unit u = GetTriggerUnit()
    local integer index = GetUnitIndex(u)
    local integer i = 1
    
    //call BJDebugMsg("|c0000FF00" + "OnDamage")
    
    if ignore[index] then
        call BJDebugMsg("|c0000FF00" + "endless requrzion prevented")
    else
        // mutex :D
        set ignore[index] = true
        call TriggerEvaluate(GlobalOnDamageTrigger)  // faster than execute
        set ignore[index] = false
    endif

    set u = null 
    return false
endfunction 


// makes sure one and only one OnDamage trigger is created per unit
private function LinkOnDamageTrigger takes unit u returns nothing
    local integer index = GetUnitIndex(u)
    local trigger trig = OnDamagePerUnit[index]
    
    // index was recycled so we destroy trigger because 
    // it belongs to previous unit on that index
    if (trig != null) then
        call DestroyTrigger(trig)
    endif

    set trig = CreateTrigger()
    
    //call BJDebugMsg("Registering OnDamage for " + GetUnitName(u))
    call TriggerRegisterUnitEvent(trig, u, EVENT_UNIT_DAMAGED)   
    call TriggerAddCondition(trig,Condition(function OnDamage))    
    
    set trig = null
endfunction

//Add damage trigger to units who enter map
private function AddTriggers takes nothing returns boolean
    local unit u = GetTriggerUnit()
    call LinkOnDamageTrigger(u)
    set u = null
    return false
endfunction

//Add damage trigger to preplaced units
private function FirstGroup takes nothing returns nothing
    local unit u = GetEnumUnit()   
    call LinkOnDamageTrigger(u)
    set u = null
endfunction

// Init
private function Init takes nothing returns nothing
    local trigger entmap_trig
    local group g
    
    // One trigger to OnDamage them all
    set GlobalOnDamageTrigger = CreateTrigger()
    
    // register OnDamage for preplaced units
    set g = CreateGroup()
    call GroupEnumUnitsInRect(g,bj_mapInitialPlayableArea, null)
    call ForGroup(g,function FirstGroup)
    call DestroyGroup(g)
    set g = null    
   
    // create trigger that registers OnDamage for units that enter the map
    set entmap_trig = CreateTrigger()
    call TriggerRegisterEnterRectSimple(entmap_trig, bj_mapInitialPlayableArea)
    call TriggerAddCondition(entmap_trig,Condition(function AddTriggers))
    set entmap_trig = null
endfunction

endlibrary